Compruebe si existe una tabla temporal y elimínela si existe antes de crear una tabla temporal

Estoy usando el siguiente código para verificar si la tabla temporal existe y soltar la tabla si existe antes de crear nuevamente. Funciona bien siempre que no cambie las columnas. Si agrego una columna más tarde, aparecerá un error que dice "columna no válida". Por favor, hágame saber lo que estoy haciendo mal.

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
)

select company, stepid, fieldid from #Results

--Works fine to this point

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
    NewColumn            NVARCHAR(50)
)

select company, stepid, fieldid, NewColumn from #Results

--Does not work

No puedo reproducir el error.

Quizás no entiendo el problema.

Lo siguiente funciona bien para mí en SQL Server 2005, con la columna "foo" adicional que aparece en el segundo resultado de selección:

IF OBJECT_ID('tempdb..#Results') IS NOT NULL DROP TABLE #Results
GO
CREATE TABLE #Results ( Company CHAR(3), StepId TINYINT, FieldId TINYINT )
GO
select company, stepid, fieldid from #Results
GO
ALTER TABLE #Results ADD foo VARCHAR(50) NULL
GO
select company, stepid, fieldid, foo from #Results
GO
IF OBJECT_ID('tempdb..#Results') IS NOT NULL DROP TABLE #Results
GO

La declaración debe ser del orden

1. Alterar la declaración para la mesa
2. VAMOS
3. Seleccionar declaración.

Sin 'GO' en el medio, todo se considerará como un solo script y cuando la instrucción select busca la columna, no se encontrará.

Con 'GO', considerará la parte del script hasta 'GO' como un solo lote y se ejecutará antes de entrar en la consulta después de 'GO'.

En lugar de droppingvolver a crear la tabla temporal, puede truncatereutilizarla

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    Truncate TABLE #Results
else
    CREATE TABLE #Results
    (
        Company             CHAR(3),
        StepId              TINYINT,
        FieldId             TINYINT,
    )

Si está utilizando Sql Server 2016o Azure Sql Databaseluego utiliza la sintaxis siguiente para descartar la tabla temporal y volver a crearla. Más información aquí MSDN

Sintaxis

DROP TABLE [IF EXISTS] [nombre_base_datos. [nombre_esquema]. El | nombre_esquema. ] nombre_tabla [, ... n]

Consulta:

DROP TABLE IF EXISTS tempdb.dbo.#Results
CREATE TABLE #Results
  (
   Company             CHAR(3),
   StepId              TINYINT,
   FieldId             TINYINT,
  )

Creo que el problema es que necesita agregar una declaración GO en el medio para separar la ejecución en lotes. Como el segundo script de caída, es decir, IF OBJECT_ID('tempdb..#Results') IS NOT NULL DROP TABLE #Resultsno dejó caer la tabla temporal como parte de un solo lote. ¿Puedes probar el siguiente script?

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
)

GO

select company, stepid, fieldid from #Results

IF OBJECT_ID('tempdb..#Results') IS NOT NULL
DROP TABLE #Results

CREATE TABLE #Results
(
    Company                CHAR(3),
    StepId                TINYINT,
    FieldId                TINYINT,
    NewColumn            NVARCHAR(50)
)

GO

select company, stepid, fieldid, NewColumn from #Results

Esto podría lograrse con una sola línea de código:

IF OBJECT_ID('tempdb..#tempTableName') IS NOT NULL DROP TABLE #tempTableName;   

Esto funcionó para mí: social.msdn.microsoft.com/Forums/en/transactsql/thread/02c6da90-954d-487d-a823-e24b891ec1b0?prof=required

if exists (
    select  * from tempdb.dbo.sysobjects o
    where o.xtype in ('U') 

   and o.id = object_id(N'tempdb..#tempTable')
)
DROP TABLE #tempTable;

Solo un pequeño comentario de mi parte ya OBJECT_IDque no funciona para mí. Siempre devuelve eso

`#tempTable no existe

..even pesar de que hace existir. Acabo de encontrar que está almacenado con un nombre diferente (pospuesto con _guiones bajos) así:

#tempTable________

Esto funciona bien para mi:

IF EXISTS(SELECT [name] FROM tempdb.sys.tables WHERE [name] like '#tempTable%') BEGIN
   DROP TABLE #tempTable;
END;

Ahora puede usar la sintaxis a continuación si está utilizando una de las nuevas versiones de SQL Server (2016+).

DROP TABLE IF EXISTS schema.yourtable(even temporary tables #...)

pmac72 está usando GO para dividir la consulta en lotes y está usando ALTER.

Parece que está ejecutando el mismo lote pero ejecutándolo dos veces después de cambiarlo: DROP ... CREATE ... edit ... DROP ... CREATE ..

Quizás publique su código exacto para que podamos ver lo que está sucediendo.

Por lo general, aparece este error cuando ya he creado la tabla temporal; el código que verifica la instrucción SQL en busca de errores ve la tabla temporal "antigua" en su lugar y devuelve un recuento incorrecto del número de columnas en las declaraciones posteriores, como si la tabla temporal nunca se descartara.

Después de cambiar el número de columnas en una tabla temporal después de crear una versión con menos columnas, suelte la tabla y LUEGO ejecute su consulta.

Hace poco vi un DBA hacer algo similar a esto:

begin try
    drop table #temp
end try

begin catch 
    print 'table does not exist'
end catch 

create table #temp(a int, b int)

Mi código usa una Sourcetabla que cambia y una Destinationtabla que debe coincidir con esos cambios.

-- 
-- Sample SQL to update only rows in a "Destination" Table
--  based on only rows that have changed in a "Source" table
--


--
-- Drop and Create a Temp Table to use as the "Source" Table
--
IF OBJECT_ID('tempdb..#tSource') IS NOT NULL drop table #tSource
create table #tSource (Col1 int, Col2 int, Col3 int, Col4 int)

--
-- Insert some values into the source
--
Insert #tSource (Col1, Col2, Col3, Col4) Values(1,1,1,1)
Insert #tSource (Col1, Col2, Col3, Col4) Values(2,1,1,2)
Insert #tSource (Col1, Col2, Col3, Col4) Values(3,1,1,3)
Insert #tSource (Col1, Col2, Col3, Col4) Values(4,1,1,4)
Insert #tSource (Col1, Col2, Col3, Col4) Values(5,1,1,5)
Insert #tSource (Col1, Col2, Col3, Col4) Values(6,1,1,6)

--
-- Drop and Create a Temp Table to use as the "Destination" Table
--
IF OBJECT_ID('tempdb..#tDest') IS NOT NULL drop Table #tDest
create table #tDest (Col1 int, Col2 int, Col3 int, Col4 int)

--
-- Add all Rows from the Source to the Destination
--
Insert #tDest
Select Col1, Col2, Col3, Col4 from #tSource


--
-- Look at both tables to see that they are the same
--
select *
from #tSource
Select *
from #tDest

--
-- Make some changes to the Source
--
update #tSource
    Set Col3=19
    Where Col1=1
update #tSource
    Set Col3=29
    Where Col1=2
update #tSource
    Set Col2=38
    Where Col1=3
update #tSource
    Set Col2=48
    Where Col1=4

--
-- Look at the Differences
-- Note: Only 4 rows are different. 2 Rows have remained the same.
--
Select Col1, Col2, Col3, Col4
from #tSource
except
Select Col1, Col2, Col3, Col4
from #tDest

--
-- Update only the rows that have changed
-- Note: I am using Col1 like an ID column
--
Update #tDest
    Set Col2=S.Col2,
        Col3=S.Col3,
        Col4=S.Col4
From    (   Select Col1, Col2, Col3, Col4
            from #tSource
            except
            Select Col1, Col2, Col3, Col4
            from #tDest
        ) S
Where #tDest.Col1=S.Col1 

--
-- Look at the tables again to see that
--  the destination table has changed to match
--  the source table.

select *
from #tSource
Select *
from #tDest

--
-- Clean Up
--
drop table #tSource
drop table #tDest

Sí, "columna no válida", este error surgió de la línea "seleccionar empresa, stepid, fieldid, NewColumn de #Results".

Hay dos fases de ejecución de t-sql,

primero, analizando, en esta fase, el servidor sql verifica la corrección de la cadena sql enviada, incluida la columna de la tabla, y optimiza su consulta para una recuperación más rápida.

segundo, corriendo, recuperando los datos.

Si la tabla #Results existe, el proceso de análisis verificará que las columnas que especificó sean válidas o no, de lo contrario (la tabla no existe) el análisis se pasará por las columnas de comprobación como usted especificó.

Cuando cambia una columna en una tabla temporal, debe soltar la tabla antes de volver a ejecutar la consulta. (Sí, es molesto. Justo lo que tienes que hacer).

Siempre he asumido que esto se debe a que el analizador realiza la comprobación de "columna no válida" antes de ejecutar la consulta, por lo que se basa en las columnas de la tabla antes de que se descarte ... y eso es lo que pnbs también dijo.