¿Cómo ver todas las etiquetas de hoja en MS excel?

Tengo un archivo de MS Excel con muchas hojas y necesito moverme de ellas.

¿Cómo puedo enumerar todas las etiquetas y moverme a una específica?

Interesante. Acabo de escribir tres macros que harán esto razonablemente bien. La primera macro genera una hoja de resumen (llamada sh_summary ) al final de su libro de trabajo, y lo selecciona. Luego, desde esta nueva hoja de resumen, seleccione uno de los nombres de hoja que desee (por ejemplo, seleccione la celda A2) y luego inicie la segunda macro que seleccionará / navegará a la hoja que eligió. La tercera macro lo llevará de regreso a la hoja de resumen. Las macros 2nd + 3rd deben ser de acceso directo, para una navegación rápida.

1:

Sub findSheets()
    Dim sheetNum As Integer
    Dim i As Integer
    Dim theSh(999)

    'count sheets:
    sheetNum = ActiveWorkbook.Worksheets.Count

    'check for a summary sheet and delete it if found:
    For i = 1 To sheetNum
        If ActiveWorkbook.Worksheets(i).Name = "sh_summary" Then
            Application.DisplayAlerts = False
            ActiveWorkbook.Worksheets(i).Delete
            Application.DisplayAlerts = True
        End If
    Next i

    'count sheets again:
    sheetNum = ActiveWorkbook.Worksheets.Count

    'get sheet names
    For i = 1 To sheetNum
        theSh(i) = ActiveWorkbook.Worksheets(i).Name
    Next i

    'create summary sheet:
    Sheets.Add After:=Sheets(Sheets.Count)
    Sheets(Sheets.Count).Select
    Sheets(Sheets.Count).Name = "sh_summary"

    'print sheet names on summary sheet:
    For i = 1 To sheetNum
        Cells(1, 1).Value = "Worksheet summary:"
        Cells((1 + i), 1).Value = theSh(i)
    Next i
End Sub

2:

Sub navToSheet()
    On Error Resume Next
    ActiveWorkbook.Worksheets(ActiveCell.Value).Select
    If Err.Number <> 0 Then
        MsgBox "Can't find sheet - select and try again."
        Err.Clear
    End If
End Sub

3:

Sub navToSummary()
    On Error Resume Next
    ActiveWorkbook.Worksheets("sh_summary").Select
    If Err.Number <> 0 Then
        MsgBox "Can't find summary sheet."
        Err.Clear
    End If
End Sub