¿Cómo reemplazar la celda de la tabla vacía en la palabra 2007 con '-'?

¿Cómo reemplazar la celda de la tabla vacía en la palabra con '-'? Parece que es imposible localizar una celda vacía en la tabla de palabras, tenga en cuenta que vacío = nada en ella.

Desafortunadamente, Word no tiene una forma simple de encontrar celdas vacías. De hecho, tendrás que hacer algunos VBA.

Desde http://word.tips.net/T010772_Placing_Text_in_Empty_Table_Cells.html , Encuentro 2 métodos: 1 para reemplazar todas las celdas de la tabla vacía en todas las tablas vacías:

Sub ProcCells1()
    Dim tTable As Table
    Dim cCell As Cell
    Dim sTemp As String

    sTemp = "-"

    For Each tTable In ActiveDocument.Range.Tables
        For Each cCell In tTable.Range.Cells
            'An apparently empty cell contains an end of cell marker
            If Len(cCell.Range.Text) < 3 Then
                cCell.Range = sTemp
            End If
        Next
    Next
    Set oCell = Nothing
    Set tTable = Nothing
End Sub

El otro método solo hace la tabla seleccionada actualmente:

Sub ProcCells2()
    Dim tTable As Table
    Dim cCell As Cell
    Dim sTemp As String

    sTemp = "-"

    If Selection.Information(wdWithInTable) Then
        Set tTable = Selection.Tables(1)
        For Each cCell In tTable.Range.Cells
            'An apparently empty cell contains an end of cell marker
            If Len(cCell.Range.Text) < 3 Then
                cCell.Range = sTemp
            End If
        Next
    End If
    Set oCell = Nothing
    Set tTable = Nothing
End Sub

Otra opción es copiar su tabla a Excel, usar las funciones de selección avanzada allí para seleccionar todas las celdas vacías y agregar el guión allí. A continuación, puede copiar la tabla de nuevo a la palabra.