¿Cómo calculo el número de meses entre dos fechas en Excel? [duplicar]

8

Tengo dos columnas en Microsoft Excel: F es la columna con la fecha de finalización del servicio; E es la columna con la fecha en que comenzó el servicio.

¿Cómo calculo y notifico el número de meses servidos para cada persona?

microsoft-excel Terrance Drake
fuente
Indíquenos el resultado deseado con (p. Ej.) 14.3.2014 - 12.7.2014: (a) 4 meses (el cuarto no está completo) o (b) 5 meses (contando cada mes tocado) o (c) 3 meses (solo conteo de meses completos) o (d) 3.9 meses.
Guntbert
1
La respuesta aquí es mejor que el "original" vinculado en esta pregunta
Jayan

Respuestas:

16

La función DATEDIF le proporciona explícitamente el número de meses entre dos fechas: se redondea hacia abajo

=DATEDIF(A2,B2,"m")

donde A2 es la primera de las dos fechas

Si desea redondear al mes completo "más cercano", puede usar esta versión

=DATEDIF(A2,B2+15,"m")

Si no le importa el día y cualquier fecha en enero a cualquier fecha en marzo es de 3 meses, puede usar esta versión

=DATEDIF(A2-DAY(A2)+1,B2,"m")+1

barry houdini
fuente
Funciona en Google Sheets también.
Adriano P
Puede usarlo =(B2 - A1)/(365/12)si desea una respuesta no redondeada, considera que un mes tiene un promedio de 365/12 días de duración
aljgom
3

Hay un KB de Microsoft que cubre este mismo tema aquí

Proporciona dos soluciones, dependiendo de si desea redondear los meses hacia abajo o hacia arriba.

Redondeo:

=(YEAR(LDate)-YEAR(EDate))*12+MONTH(LDate)-MONTH(EDate)

Redondear a la baja:

=IF(DAY(LDate)>=DAY(EDate),0,-1)+(YEAR(LDate)-YEAR(EDate))*12+MONTH(LDate)-MONTH(EDate)

En ambos casos, EDate es la celda que contiene la fecha anterior, y LDate es la celda que contiene la fecha posterior.

kenkh
fuente