En Outlook 2010, ¿hay alguna forma de ver los recordatorios que están dormitando actualmente?

¿Hay alguna forma en Outlook 2010 para obtener una lista de elementos que actualmente están dormidos? Por ejemplo, digamos que dos semanas después, programé un recordatorio para que aparezca el viernes en una importante reunión de almuerzo el lunes siguiente (me gusta que me recuerden las tareas del lunes antes del fin de semana). Cuando el recordatorio aparece el viernes, lo poseo tres días para que vuelva a aparecer justo antes del almuerzo del lunes. Luego, el lunes da vueltas y mi memoria está borrosa y estoy un poco paranoico por haber descartado accidentalmente el recordatorio el viernes en lugar de dormitarlo correctamente. Todavía puedo ver la cita original en mi calendario, pero debo asegurarme de que en realidad voy a tener un recordatorio cuando lo espero para que no me pierda la reunión.

¿Hay alguna forma en Outlook 2010 para obtener una lista de los recordatorios que actualmente están dormidos? Esto también sería útil para aquellos casos en los que complete una tarea cuyo recordatorio había dormido hasta más tarde, y ahora quiero recuperar el recordatorio dormido y cancelarlo.

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

Si no está familiarizado con VBA vea Página de explicación de Slipstick . Encontrará información sobre:

• configuración de seguridad de macros;
• dónde colocar el código (puede usar un módulo regular con Insertar | Módulo); y
• cómo crear un botón

De acuerdo a esto Ver artículos dormidos mensaje del foro, no es posible ver una lista de elementos dormidos. La publicación sugiere que puede ver una cantidad limitada de información útil al crear una vista personalizada que muestra algunos de los campos de recordatorio.

Intente hacer clic en la pestaña Calendario, seleccione Ver y Cambiar vista. Luego seleccione Lista. Esto parece mostrar una lista de todos los recordatorios.