agregando celdas con fechas

Estoy tratando de sumar un total de un rango de celdas entre los rangos de fechas, es decir, la columna n tiene cantidades de $ la columna d tiene las fechas de transacción, es decir, 1/3/2015 o 25/3/2015 o 25/4/2015 columna b tiene el texto que dice drp o distribución - reinv

En otra celda estoy tratando de sumar o totalizar (en la columna n) con el valor de un rango de fechas diferentes (columna d) que contienen texto diferente (columna b), es decir, la celda n48 es 50, n65 es 85, n165 es 36

con las fechas, es decir, la celda d48 es el 1/3/2015, d65 es el 25/3/2015 y d165 es el 25/4/2015

con texto diferente que dice drp o distribución - reinv es decir, la celda b48 es drp, b65 es distribución - reinv, b165 es drp

Si quisiera sumar las cantidades entre el 1/3/2015 al 31/3/2015 con drp, entonces el total sería 50. Además, si quisiera sumar las cantidades entre el 1/4/2015 al 30/4/2015 con drp la suma total sería 36 Si quisiera sumar las cantidades entre el 1/3/2015 al 31/3/2015 con drp y distribución - reinv la suma sería 115

¿Cuál sería la fórmula para estas diferentes preguntas?

Espero que puedan ayudar, me ha estado volviendo loco y no puedo resolverlo

Como dijo Michthan, una tabla dinámica puede hacer esto, pero puede ser desalentador para alguien que nunca ha trabajado con ellos antes. Sin embargo, la función SUMIFS () es exactamente lo que necesita en este caso:

Escenario 1:

=SUMIFS($N:$N,$B:$B,"drp",$D:$D,">="&DATE(2015,3,1),$D:$D,"<="&DATE(2015,3,31))

Escenario 2:

=SUMIFS($N:$N,$B:$B,"drp",$D:$D,">="&DATE(2015,4,1),$D:$D,"<="&DATE(2015,4,30))

Escenario 3:

=SUM(SUMIFS($N:$N,$B:$B,{"drp","distribution - reinv"},$D:$D,">="&DATE(2015,3,1),$D:$D,"<="&DATE(2015,3,31)))

Si bien estos funcionarán exactamente para las condiciones que usted indicó (y puede editar las fechas en las fórmulas como desee), no son muy flexibles en caso de que desee cambiar sus criterios. Sería mejor mantener sus criterios en algunas celdas como $ O $ 1: $ O $ 4 y consultar esas celdas en la fórmula de la siguiente manera:

$O$1 = drp [text]
$O$2 = 1/3/2015 [start date]
$O$3 = 31/3/2015 [end date]

Y la fórmula se convertiría

=SUMIFS($N:$N,$B:$B,$O$1,$D:$D,">="&$O$2,$D:$D,"<="&$O$3)

Nota al margen: No pude obtener múltiples criterios de texto OR () con referencias de celda para trabajar, incluso dentro de una función INDIRECTO (). Si alguien puede proporcionar orientación adicional, estoy seguro de que Murray lo agradecería.