Fórmula para extraer los datos dentro del segundo paréntesis consecutivo [cerrado]

De lo siguiente, quiero extraer los datos entre paréntesis si es solo un número.

Nissan - Lanzamiento de X-Trail (mayo) (junio) - SO9158518 (65124817) Turismo - Curioso 2017 (Noticias) (44124469)

Pruebe esta función definida por el usuario:

Public Function parens(t As String) As String
    Dim i As Long, L As Long, CH As String
    Dim x As String, y As String, temp As String
    Dim ary() As String, Kapture As Boolean, a As Variant
    Dim j As Long

    parens = ""
    L = Len(t)
    x = "("
    y = ")"
    Kapture = False
    temp = ""
    j = 1

    For i = 1 To L
        CH = Mid(t, i, 1)
        If CH = x Then
            Kapture = True
            temp = ""
            ReDim Preserve ary(1 To j)
            j = j + 1
        ElseIf CH = y Then
            ary(UBound(ary)) = temp
        Else
            If Kapture Then temp = temp & CH
        End If
    Next i

    For Each a In ary
        If IsNumeric(a) Then
            parens = a
            Exit Function
        End If
    Next a
End Function

Extrae material entre paréntesis hasta que encuentra un valor numérico.

Las funciones definidas por el usuario (UDF) son muy fáciles de instalar y usar:

1. ALT-F11 abre la ventana VBE
2. ALT-I ALT-M abre un nuevo módulo
3. pegue las cosas y cierre la ventana VBE

Si guarda el libro, el UDF se guardará con él. Si está utilizando una versión de Excel más tarde que 2003, debe guardar el archivo como .xlsm en lugar de .xlsx

Para eliminar el UDF:

1. abrir la ventana VBE como se muestra arriba
2. borrar el código
3. cierra la ventana de VBE

Para usar el UDF de Excel:

=parens(A1)

Para obtener más información sobre las macros en general, consulte:

http://www.mvps.org/dmcritchie/excel/getstarted.htm

y

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

y para detalles sobre UDF, ver:

http://www.cpearson.com/excel/WritingFunctionsInVBA.aspx

¡Las macros deben estar habilitadas para que esto funcione!