TSQL - ¿Cómo usar GO dentro de un bloque BEGIN .. END?

Estoy generando un script para migrar automáticamente los cambios de varias bases de datos de desarrollo a la etapa de preparación / producción. Básicamente, se necesitan varios scripts de cambio y los fusiona en un solo script, envolviendo cada script en una IF whatever BEGIN ... ENDdeclaración.

Sin embargo, algunos de los scripts requieren una GOdeclaración para que, por ejemplo, el analizador de SQL conozca una nueva columna después de que se cree.

ALTER TABLE dbo.EMPLOYEE 
ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO -- Necessary, or next line will generate "Unknown column:  EMP_IS_ADMIN"
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Sin embargo, una vez que envuelvo eso en un IFbloque:

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
    GO
    UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever
END

Falla porque estoy enviando un BEGINmensaje sin coincidencia END. Sin embargo, si elimino el GO, vuelve a quejarse de una columna desconocida.

¿Hay alguna forma de crear y actualizar la misma columna dentro de un solo IFbloque?

Tuve el mismo problema y finalmente logré resolverlo usando SET NOEXEC .

IF not whatever
BEGIN
    SET NOEXEC ON; 
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

SET NOEXEC OFF; 

GO no es SQL, es simplemente un separador de lotes utilizado en algunas herramientas de MS SQL.

Si no lo usa, debe asegurarse de que las declaraciones se ejecuten por separado, ya sea en diferentes lotes o mediante el uso de SQL dinámico para la población (gracias @gbn):

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL;

    EXEC ('UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever')
END

Puede intentar sp_executesqldividir el contenido entre cada GOdeclaración en una cadena separada para que se ejecute, como se muestra en el siguiente ejemplo. Además, hay una variable @statementNo para rastrear qué declaración se está ejecutando para una fácil depuración donde ocurrió una excepción. Los números de línea estarán relacionados con el comienzo del número de declaración relevante que causó el error.

BEGIN TRAN

DECLARE @statementNo INT
BEGIN TRY
    IF 1=1
    BEGIN
        SET @statementNo = 1
        EXEC sp_executesql
            N'  ALTER TABLE dbo.EMPLOYEE
                    ADD COLUMN EMP_IS_ADMIN BIT NOT NULL'

        SET @statementNo = 2
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1'

        SET @statementNo = 3
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1x'
    END
END TRY
BEGIN CATCH
    PRINT 'Error occurred on line ' + cast(ERROR_LINE() as varchar(10)) 
       + ' of ' + 'statement # ' + cast(@statementNo as varchar(10)) 
       + ': ' + ERROR_MESSAGE()
    -- error occurred, so rollback the transaction
    ROLLBACK
END CATCH
-- if we were successful, we should still have a transaction, so commit it
IF @@TRANCOUNT > 0
    COMMIT

También puede ejecutar fácilmente declaraciones de varias líneas, como se demuestra en el ejemplo anterior, simplemente envolviéndolas entre comillas simples ( '). No olvide escapar las comillas simples contenidas dentro de la cadena con una comilla simple doble ( '') al generar los scripts.

Finalmente logré que funcionara reemplazando cada instancia de GOen su propia línea con

END
GO

---Automatic replacement of GO keyword, need to recheck IF conditional:
IF whatever
BEGIN

Esto es muy preferible a envolver cada grupo de declaraciones en una cadena, pero aún está lejos de ser ideal. Si alguien encuentra una solución mejor, publíquela y la aceptaré.

Puede incluir las declaraciones en BEGIN y END en lugar del GO entre

IF COL_LENGTH('Employees','EMP_IS_ADMIN') IS NULL --Column does not exist
BEGIN
    BEGIN
        ALTER TABLE dbo.Employees ADD EMP_IS_ADMIN BIT
    END

    BEGIN
        UPDATE EMPLOYEES SET EMP_IS_ADMIN = 0
    END
END

(Probado en la base de datos Northwind)

Editar: (Probablemente probado en SQL2012)

Puede probar esta solución:

if exists(
SELECT...
)
BEGIN
PRINT 'NOT RUN'
RETURN
END

--if upper code not true

ALTER...
GO
UPDATE...
GO

He usado RAISERRORen el pasado para esto

IF NOT whatever BEGIN
    RAISERROR('YOU''RE ALL SET, and sorry for the error!', 20, -1) WITH LOG
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Puede incorporar declaraciones GOTOy LABELpara omitir el código, dejando las GOpalabras clave intactas.