SQL Server SELECT INTO @variable?

Tengo el siguiente código en uno de mis Sql (2008) Stored Procs que se ejecuta perfectamente:

    CREATE PROCEDURE [dbo].[Item_AddItem]
        @CustomerId uniqueidentifier,
        @Description nvarchar(100),
        @Type int,
        @Username nvarchar(100),
    AS
    BEGIN

        DECLARE @TopRelatedItemId uniqueidentifier;
        SET @TopRelatedItemId = 
        (
           SELECT top(1) RelatedItemId 
           FROM RelatedItems 
           WHERE CustomerId = @CustomerId
        ) 

        DECLARE @TempItem TABLE
        (
            ItemId uniqueidentifier,
            CustomerId uniqueidentifier,
            Description nvarchar(100),
            Type int,
            Username nvarchar(100),
            TimeStamp datetime
        );

        INSERT INTO Item
        OUTPUT INSERTED.* INTO @TempItem
        SELECT NEWID(), @CustomerId, @Description, @Type, @Username, GETDATE()

        SELECT
            ItemId,
            CustomerId,
            @TopRelatedItemId,
            Description,
            Type,
            Username,
            TimeStamp
        FROM
            @TempItem
END
GO

Entonces la pregunta para ustedes es si existe la posibilidad de hacer algo en la línea de:

DECLARE @TempCustomer TABLE
(
   CustomerId uniqueidentifier,
   FirstName nvarchar(100),
   LastName nvarchar(100),
   Email nvarchar(100)
);
SELECT 
    CustomerId, 
    FirstName, 
    LastName, 
    Email 
INTO 
    @TempCustomer 
FROM 
    Customer
WHERE 
    CustomerId = @CustomerId

¿Para poder reutilizar estos datos de la memoria en otras declaraciones siguientes? SQL Server se ajusta a la declaración anterior, sin embargo, no quiero tener que crear variables separadas e inicializar cada una de ellas a través de una declaración SELECT separada en la misma tabla ... ¡¡¡UGH !!!

¿Alguna sugerencia sobre cómo lograr algo similar sin múltiples consultas en la misma tabla?

No puede SELECCIONAR ... EN ... una TABLA VARIABLE. Lo mejor que puede hacer es crearlo primero, luego insertarlo. Tu segundo fragmento tiene que ser

DECLARE @TempCustomer TABLE
(
   CustomerId uniqueidentifier,
   FirstName nvarchar(100),
   LastName nvarchar(100),
   Email nvarchar(100)
);
INSERT INTO 
    @TempCustomer 
SELECT 
    CustomerId, 
    FirstName, 
    LastName, 
    Email 
FROM 
    Customer
WHERE 
    CustomerId = @CustomerId

Si desea simplemente asignar algunas variables para su uso posterior, puede hacerlas de una sola vez con algo en esta línea:

declare @var1 int,@var2 int,@var3 int;

select 
    @var1 = field1,
    @var2 = field2,
    @var3 = field3
from
    table
where
    condition

Si ese es el tipo de cosas que buscas

Puedes hacerlo:

SELECT 
    CustomerId, 
    FirstName, 
    LastName, 
    Email
INTO #tempCustomer 
FROM 
    Customer
WHERE 
    CustomerId = @CustomerId

Entonces despúes

SELECT CustomerId FROM #tempCustomer

no necesita declarar la estructura de #tempCustomer

Parece que su sintaxis está ligeramente fuera. Esto tiene algunos buenos ejemplos.

DECLARE @TempCustomer TABLE
(
   CustomerId uniqueidentifier,
   FirstName nvarchar(100),
   LastName nvarchar(100),
   Email nvarchar(100)
);
INSERT @TempCustomer 
SELECT 
    CustomerId, 
    FirstName, 
    LastName, 
    Email 
FROM 
    Customer
WHERE 
    CustomerId = @CustomerId

Entonces despúes

SELECT CustomerId FROM @TempCustomer

Parece que quieres tablas temporales. http://www.sqlteam.com/article/temporary-tables

Tenga en cuenta que #TempTable está disponible en todo su SP.

Tenga en cuenta que ## TempTable está disponible para todos.

Encontré su pregunta buscando una solución al mismo problema; y lo que otras respuestas no señalan es una forma de usar una variable para cambiar el nombre de la tabla para cada ejecución de su procedimiento en forma permanente, no temporal.

Hasta ahora, lo que hago es concatenar todo el código SQL con las variables a utilizar. Me gusta esto:

declare @table_name as varchar(30)
select @table_name = CONVERT(varchar(30), getdate(), 112)
set @table_name = 'DAILY_SNAPSHOT_' + @table_name

EXEC('
        SELECT var1, var2, var3
        INTO '+@table_name+'
        FROM my_view
        WHERE string = ''Strings must use double apostrophe''
    ');

Espero que ayude, pero podría ser engorroso si el código es demasiado grande, así que si has encontrado una mejor manera, ¡comparte!

"SELECT *
  INTO 
    @TempCustomer 
FROM 
    Customer
WHERE 
    CustomerId = @CustomerId"

Lo que significa crear una nueva @tempCustomervariable de tabla e insertar datos del cliente. Ya lo había declarado anteriormente, así que no es necesario volver a declararlo. Mejor ir con

INSERT INTO @tempCustomer SELECT * FROM Customer