Obtener el resultado de SQL dinámico en una variable para sql-server

116

Ejecutar SQL dinámico de la siguiente manera en el procedimiento almacenado:

DECLARE @sqlCommand nvarchar(1000)
DECLARE @city varchar(75)
SET @city = 'London'
SET @sqlCommand = 'SELECT COUNT(*) FROM customers WHERE City = @city'
EXECUTE sp_executesql @sqlCommand, N'@city nvarchar(75)', @city = @city

¿Cómo utilizo el valor de la columna de recuento (*) como valor de retorno en el SP?

sql sql-server sql-server-2005 tsql dynamic-sql Peter Lindholm
fuente

202

DECLARE @sqlCommand nvarchar(1000)
DECLARE @city varchar(75)
declare @counts int
SET @city = 'New York'
SET @sqlCommand = 'SELECT @cnt=COUNT(*) FROM customers WHERE City = @city'
EXECUTE sp_executesql @sqlCommand, N'@city nvarchar(75),@cnt int OUTPUT', @city = @city, @cnt=@counts OUTPUT
select @counts as Counts

Sabio
fuente

4

+1: Me adelantaste, necesitas declarar una variable y marcarla como SALIDA. Para obtener más información y una lectura recomendada para SQL Server SQL dinámico, consulte La maldición y las bendiciones del SQL dinámico

OMG Ponies

1

Gracias. La palabra clave OUTPUT en N '@ city nvarchar (75), @ cnt int OUTPUT' era lo que me faltaba.

Peter Lindholm

1

¿No hay ninguna solución que no requiera agregar una variable de salida a la declaración dinámica?

Tab Alleman

2

Probablemente haya intentado esto, pero ¿sus especificaciones son tales que puede hacer esto?

DECLARE @city varchar(75)
DECLARE @count INT
SET @city = 'London'
SELECT @count = COUNT(*) FROM customers WHERE City = @city

Puntilla
fuente

2

versión dinámica

    ALTER PROCEDURE [dbo].[ReseedTableIdentityCol](@p_table varchar(max))-- RETURNS int
    AS
    BEGIN
        -- Declare the return variable here
       DECLARE @sqlCommand nvarchar(1000)
       DECLARE @maxVal INT
       set @sqlCommand = 'SELECT @maxVal = ISNULL(max(ID),0)+1 from '+@p_table
       EXECUTE sp_executesql @sqlCommand, N'@maxVal int OUTPUT',@maxVal=@maxVal OUTPUT
       DBCC CHECKIDENT(@p_table, RESEED, @maxVal)
    END


exec dbo.ReseedTableIdentityCol @p_table='Junk'

Ab Bennett
fuente

0

DECLARE @sqlCommand nvarchar(1000)
DECLARE @city varchar(75)
DECLARE @cnt int
SET @city = 'London'
SET @sqlCommand = 'SELECT @cnt=COUNT(*) FROM customers WHERE City = @city'
EXECUTE sp_executesql @sqlCommand, N'@city nvarchar(75)', @city = @city
RETURN @cnt

CristiC
fuente

1

Creo que se cortó tu respuesta.

Sage

Msg 137, Must declare the scalar variable "@cnt". msg 178, A RETURN statement with a return value cannot be used in this context.. Un buen trabajo, hermano))

it3xl

0

esto podría ser una solución?

declare @step2cmd nvarchar(200)
DECLARE @rcount NUMERIC(18,0)   
set @step2cmd = 'select count(*) from uat.ap.ztscm_protocollo' --+ @nometab
EXECUTE @rcount=sp_executesql @step2cmd
select @rcount

Stefano Pedone
fuente

-2

 vMYQUERY := 'SELECT COUNT(*) FROM ALL_OBJECTS WHERE OWNER = UPPER(''MFI_IDBI2LIVE'') AND OBJECT_TYPE = ''TABLE'' 
    AND OBJECT_NAME  =''' || vTBL_CLIENT_MASTER || '''';
    PRINT_STRING(VMYQUERY);
    EXECUTE IMMEDIATE  vMYQUERY INTO VCOUNTTEMP ;

PaOne
fuente

Esto no se aplica al servidor SQL.

Robert Lujo

Obtener el resultado de SQL dinámico en una variable para sql-server

Respuestas: