Consulta de hoja de cálculo de Google: ¿Puedo eliminar el encabezado de columna?

Respuestas:

188

Prueba esto:

=QUERY(H4:L35,"select sum(L) where H='First Week' label sum(L) ''")

¡Espero que ayude!

KRR
fuente
3
Acabo de probar esto en una de mis hojas y elimina el encabezado de los resultados devueltos; esto debe marcarse como la respuesta correcta. :)
FooBar
1
Esto es genial y funciona, pero ¿alguien podría explicar por qué se necesitan las dos comillas simples al final? ¿Qué hace eso desde una perspectiva de sintaxis?
y-i_guy
2
La comilla simple reemplaza el encabezado de la suma con un espacio vacío. ¡Espero que eso explique tu pregunta!
KRR
2
¡Gracias por la respuesta! Necesito hacer lo mismo con más de una columna, ¡pero no puedo lograrlo! Esperaba que esto funcionara: = QUERY (H4: L35, "seleccionar suma (L), suma (H) donde H = 'Primera semana' etiqueta suma (L) '' etiqueta suma (H) ''")
Emilio Nicolás
11
LABEL B 'Label1', C 'Label2'para varias columnas
sojim2
30

=QUERY(QUERY(A1:D, "SELECT *", 1), "SELECT * OFFSET 1", 0)

La consulta externa: "SELECT * OFFSET 1"excluye la primera fila (el encabezado).

La consulta interna especifica explícitamente una fila de encabezados (a través del tercer argumento proporcionado a QUERY), mientras que la consulta externa no especifica ninguno.

user280150
fuente
3
¿Un poco de explicación?
J Fabian Meier
¿Por qué es QUERYnecesario el segundo ? ¿El parámetro "0" no elimina los encabezados, por lo que puede usarlo en el primero QUERY, como este: QUERY('Form responses 3'!$A$2:$P$1017, "SELECT max(E),max(C), max(D) WHERE B='" & B14 & "' GROUP BY B LIMIT 1 ", 0)
Steven M. Mortimer
3
Creo que OFFSET 1en la segunda consulta se eliminará la primera fila del conjunto de datos devuelto, no los encabezados de la primera fila.
Steven M. Mortimer
2
Esta respuesta puede ser más detallada, pero también es más sólida y se puede usar sin necesidad de duplicar cadenas de agregación de columnas. Incluso se puede usar con pivot, que no funciona con ninguna otra respuesta aquí.
7yl4r
1
A menos que me equivoque, esto en realidad no resuelve el desafío específico que ofrece el póster original, es decir, eliminar los encabezados que QUERY genera automáticamente al usar funciones de agregación como SUM. Cuando se usa SUM (o cualquier otra función de agregación), QUERY crea automáticamente una fila de encabezado que especifica la agregación realizada, por ejemplo, "suma". Lo hará incluso si establece los encabezados en 0 e incluso si aplica la cláusula OFFSET 1. La siguiente fórmula todavía devuelve encabezados. = CONSULTA (Hoja1! A: B, "SELECCIONAR A, SUMA (B) AGRUPAR POR UNA COMPENSACIÓN 1", 0) La respuesta aceptada resuelve este desafío.
Dave Meindl
0

Tengo una CONSULTA que devuelve el top 3. No pude hacer que esto funcione al devolver varias filas. Terminé ocultando la fila con la fórmula y ahora solo se muestran las respuestas.

Brian Wochele
fuente
0 
=INDEX(QUERY(H4:L35;"select sum(L) where H='First Week'"; -1),2,1)

Esto simplemente analiza la matriz devuelta y selecciona el segundo registro devuelto en la primera columna.

También puede hacer esto con la función de filtro que es menos intensiva en computación. 

=SUM(FILTER(L4:L35, H4:H35 = "First Week"))
Dean Falconer
fuente
-3

Vea el formato aquí .

Ejemplo:

=QUERY(B4:C38,
   "SELECT C, sum(B) where C!='' group by C label C 'Member', sum(B) 'Sum'"
)
Andy
fuente
2
El ejemplo proporcionado no devuelve un resultado sin encabezados.
Rubén