Yo uso la siguiente función

=DAYS360(A2, A35)

para calcular la diferencia entre dos fechas en mi columna. Sin embargo, la columna siempre se está expandiendo y actualmente tengo que cambiar manualmente 'A35' a medida que actualizo mi hoja de cálculo.

¿Hay alguna manera (en Hojas de cálculo de Google) de encontrar la última celda no vacía en esta columna y luego establecer dinámicamente ese parámetro en la función anterior?

Puede haber una forma más elocuente, pero esta es la forma en que se me ocurrió:

La función para encontrar la última celda poblada en una columna es:

=INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) )

Entonces, si lo combina con su función actual, se vería así:

=DAYS360(A2,INDEX( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ; ROWS( FILTER( A:A ; NOT( ISBLANK( A:A ) ) ) ) ))

Para encontrar la última celda no vacía, puede usar INDEXy MATCHfunciones como esta:

=DAYS360(A2; INDEX(A:A; MATCH(99^99;A:A; 1)))

Creo que esto es un poco más rápido y fácil.

Si A2: A contiene fechas contiguas, entonces INDICE (A2: A, COUNT (A2: A)) devolverá la última fecha. La fórmula final es

=DAYS360(A2,INDEX(A2:A,COUNT(A2:A)))

Mi favorito es:

=INDEX(A2:A,COUNTA(A2:A),1)

Entonces, para la necesidad del OP:

=DAYS360(A2,INDEX(A2:A,COUNTA(A2:A),1))

Si la columna se expandió solo por fechas agregadas contiguas como en mi caso, utilicé solo la función MAX para obtener la última fecha.

La fórmula final será:

=DAYS360(A2; MAX(A2:A)) 

Aunque la pregunta ya está respondida, hay una forma elocuente de hacerlo.

Use just the column name to denote last non-empty row of that column.

Por ejemplo:

Si sus datos están dentro A1:A100y desea poder agregar más datos a la columna A, digamos que puede ser A1:A105o incluso A1:A1234más tarde, puede usar este rango:

A1:A

Entonces, para obtener el último valor no vacío en un rango, utilizaremos 2 funciones:

• COUNTA
• ÍNDICE

La respuesta es =INDEX(B3:B,COUNTA(B3:B)).

Aquí está la explicación:

COUNTA(range) devuelve el número de valores en un rango, podemos usar esto para obtener el recuento de filas.

INDEX(range, row, col)devuelve el valor en un rango en la posición rowy col( col=1si no se especifica)

Ejemplos:

INDEX(A1:C5,1,1) = A1
INDEX(A1:C5,1) = A1 # implicitly states that col = 1
INDEX(A1:C5,1,2) = A2
INDEX(A1:C5,2,1) = B1
INDEX(A1:C5,2,2) = B2
INDEX(A1:C5,3,1) = C1
INDEX(A1:C5,3,2) = C2

Para la imagen de arriba, nuestro rango será B3:B. Así que vamos a contar cuántos valores hay en el rango B3:Bde COUNTA(B3:B)primera. En el lado izquierdo, producirá 8ya que hay 8 valores, mientras que producirá 9en el lado derecho. También sabemos que el último valor está en la primera columna del rango, B3:Bpor lo que el colparámetro INDEXdebe ser 1 y el rowparámetro debe estar COUNTA(B3:B).

PD : por favor vota la respuesta de @ bloodymurderlive ya que la escribió primero, solo la estoy explicando aquí.

Aqui hay otro más:

=indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),""))))

Con la ecuación final siendo esto:

=DAYS360(A2,indirect("A"&max(arrayformula(if(A:A<>"",row(A:A),"")))))

Las otras ecuaciones aquí funcionan, pero me gusta esta porque facilita la obtención del número de fila, lo que creo que necesito hacer con más frecuencia. Solo el número de fila sería así:

=max(arrayformula(if(A:A<>"",row(A:A),"")))

Originalmente intenté encontrar esto para resolver un problema de hoja de cálculo, pero no pude encontrar nada útil que solo diera el número de fila de la última entrada, así que espero que esto sea útil para alguien.

Además, esto tiene la ventaja adicional de que funciona para cualquier tipo de datos en cualquier orden, y puede tener filas en blanco entre filas con contenido, y no cuenta las celdas con fórmulas que evalúan "". También puede manejar valores repetidos. En general, es muy similar a la ecuación que usa max ((G: G <> "") * row (G: G)) aquí, pero hace que extraer el número de fila sea un poco más fácil si eso es lo que buscas .

Alternativamente, si desea poner un guión en su hoja, puede facilitarlo si planea hacerlo mucho. Aquí está ese resumen:

function lastRow(sheet,column) {
  var ss = SpreadsheetApp.getActiveSpreadsheet();
  if (column == null) {
    if (sheet != null) {
       var sheet = ss.getSheetByName(sheet);
    } else {
      var sheet = ss.getActiveSheet();
    }
    return sheet.getLastRow();
  } else {
    var sheet = ss.getSheetByName(sheet);
    var lastRow = sheet.getLastRow();
    var array = sheet.getRange(column + 1 + ':' + column + lastRow).getValues();
    for (i=0;i<array.length;i++) {
      if (array[i] != '') {       
        var final = i + 1;
      }
    }
    if (final != null) {
      return final;
    } else {
      return 0;
    }
  }
}

Aquí puede escribir lo siguiente si desea que la última fila esté en la misma hoja que está editando actualmente:

=LASTROW()

o si desea la última fila de una columna particular de esa hoja, o de una columna particular de otra hoja, puede hacer lo siguiente:

=LASTROW("Sheet1","A")

Y para la última fila de una hoja en particular en general:

=LASTROW("Sheet1")

Luego, para obtener los datos reales, puede usar indirectamente:

=INDIRECT("A"&LASTROW())

o puede modificar el script anterior en las últimas dos líneas de retorno (las dos últimas ya que tendría que colocar tanto la hoja como la columna para obtener el valor real de una columna real), y reemplazar la variable con lo siguiente:

return sheet.getRange(column + final).getValue();

y

return sheet.getRange(column + lastRow).getValue();

Una ventaja de este script es que puede elegir si desea incluir ecuaciones que evalúen "". Si no se agregan argumentos, se contarán las ecuaciones que evalúen "", pero si especifica una hoja y una columna, ahora se contarán. Además, hay mucha flexibilidad si está dispuesto a usar variaciones del guión.

Probablemente exagerado, pero todo lo posible.

¿Qué pasa con esta fórmula para obtener el último valor?

=index(G:G;max((G:G<>"")*row(G:G)))

Y esta sería una fórmula final para su tarea original:

=DAYS360(G10;index(G:G;max((G:G<>"")*row(G:G))))

Suponga que su fecha inicial está en G10.

Fui por una ruta diferente. Como sé que agregaré algo en una fila / columna uno por uno, descubro la última fila contando primero los campos que tienen datos. Lo demostraré con una columna:

=COUNT(A5:A34)

Entonces, digamos que devolvió 21. A5 está 4 filas hacia abajo, así que necesito obtener la posición 21 desde la 4ta fila hacia abajo. Puedo hacer esto usando inderect, así:

=INDIRECT("A"&COUNT(A5:A34)+4)

Es encontrar la cantidad de filas con datos y devolverme un número que estoy usando como modificador de índice.

por una fila:

=ARRAYFORMULA(INDIRECT("A"&MAX(IF(A:A<>"", ROW(A:A), ))))

para una columna:

=ARRAYFORMULA(INDIRECT(ADDRESS(1, MAX(IF(1:1<>"", COLUMN(1:1), )), 4)))

Esta parece ser la solución más simple que he encontrado para recuperar el último valor en una columna en constante expansión:

=INDEX(A:A,COUNTA(A:A),1)

Esto funciona para mi. Obtenga el último valor de la columna A en la hoja de Google:

=index(A:A,max(row(A:A)*(A:A<>"")))

(También omite filas en blanco entre si hay alguna)

Calcule la diferencia entre la última fecha en la columna A con la fecha en la celda A2.

=MAX(A2:A)-A2

Esto le dará el contenido de la última celda:

=indirect("A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>""))))

Esto le dará la dirección de la última celda:

="A"&max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

Esto le dará la fila de la última celda:

=max(ARRAYFORMULA(row(a:a)*--(a:a<>"")))

Quizás prefieras un guión. Este script es mucho más corto que el enorme publicado anteriormente por otra persona:

Vaya al editor de guiones y guarde este guión:

function getLastRow(range){
  while(range.length>0 && range[range.length-1][0]=='') range.pop();
  return range.length;
}

Una vez hecho esto, solo necesita ingresar esto en una celda:

=getLastRow(A:A)

La forma en que lo hace un aficionado es "= CONCATENATE (" A ", COUNTUNIQUE (A1: A9999))", donde A1 es la primera celda de la columna, y A9999 está más abajo de esa columna de lo que espero tener alguna entrada. Este A # resultante se puede usar con la función INDIRECTA según sea necesario.

Para encontrar el último número de fila no vacío (permitiendo espacios en blanco entre ellos), utilicé a continuación para buscar en la columna A.

=ArrayFormula(IFNA(match(2,1/(A:A<>""))))