Listar tipos de archivo conocidos

¿Cómo puedo obtener una lista de los nombres de los tipos de archivo que vim conoce actualmente?

Quiero poder hacer esto para que cuando vim no detecte automáticamente un tipo de archivo, pueda probar algunos de los tipos de archivo que vim sabe que pueden ser similares y ver si proporcionan un resaltado de sintaxis razonable.

Sé que los archivos vimscript que tratan con tipos de archivo se colocan en el ftplugindirectorio por convención, pero no es necesario que lo estén (no estoy seguro, pero no creo que los archivos vimscript en el ftplugindirectorio sean especiales), así que solo quiero pregúntele a Vim qué tipos de archivos conoce, independientemente de cómo se enteró de ellos.

Solución simple

Escriba :setfiletype (con un espacio después) , luego presione Ctrl-d.

Vea :help cmdline-completionpara más información sobre autocompletado en la línea de comando de vim.

Solución complicada

Esta solución utiliza la 'runtimepath'opción para obtener todos los directorios de sintaxis disponibles y luego obtiene una lista de los archivos vimscript en esos directorios con sus extensiones eliminadas. Esta puede no ser la forma más segura de hacerlo, por lo que las mejoras son bienvenidas:

function! GetFiletypes()
    " Get a list of all the runtime directories by taking the value of that
    " option and splitting it using a comma as the separator.
    let rtps = split(&runtimepath, ",")
    " This will be the list of filetypes that the function returns
    let filetypes = []

    " Loop through each individual item in the list of runtime paths
    for rtp in rtps
        let syntax_dir = rtp . "/syntax"
        " Check to see if there is a syntax directory in this runtimepath.
        if (isdirectory(syntax_dir))
            " Loop through each vimscript file in the syntax directory
            for syntax_file in split(glob(syntax_dir . "/*.vim"), "\n")
                " Add this file to the filetypes list with its everything
                " except its name removed.
                call add(filetypes, fnamemodify(syntax_file, ":t:r"))
            endfor
        endif
    endfor

    " This removes any duplicates and returns the resulting list.
    " NOTE: This might not be the best way to do this, suggestions are welcome.
    return uniq(sort(filetypes))
endfunction

Luego puede usar esta función de la forma que desee, como imprimir todos los valores de la lista. Podrías lograr eso así:

for f in GetFiletypes() | echo f | endfor

Tenga en cuenta que esto probablemente se puede compactar un poco, es así para facilitar la lectura. No explicaré todas las funciones y comandos utilizados aquí, pero aquí están todas las páginas de ayuda para ellos:

• :help 'runtimepath'
• :help :let
• :help :let-&
• :help split()
• :help :for
• :help expr-.
• :help :if
• :help isdirectory()
• :help glob()
• :help fnamemodify()
• :help add()
• :help uniq()
• :help sort()

Si su versión de vim es lo suficientemente reciente (v7.4.2011 +), puede solicitar tipos de archivo conocidos con la función que ahora podemos usar para ayudar a definir la autocompletación manual: getcompletion()

:echo getcompletion('', 'filetype')

Si desea restringir la lista a tipos de archivo que comienzan con a 'c', debe llamar

:echo getcompletion('c', 'filetype')

y así.

Nota: a diferencia de las soluciones que analizan los nombres de archivo y de directorio $VIMRUNTIME/{syntax,filetype}/, esta solución también analiza 'runtimepath'. Según tengo entendido, no ve nuevos tipos de archivos definidos / registrados sobre la marcha set ft=foobar, ni después de los comandos automáticos.

También puede imprimir todos los tipos de archivos en el terminal ejecutando los siguientes 2 comandos:

1)

cd $(vim -e -T dumb --cmd 'exe "set t_cm=\<C-M>"|echo $VIMRUNTIME|quit' | tr -d '\015')

2)

cat <(ls -1 ftplugin/*.vim) <(ls -1 syntax/*.vim) | tr '\n' '\0' | xargs -0 -n 1 basename | sort | uniq | cut -f 1 -d '.'

El primer comando simplemente navega a su ruta de tiempo de ejecución vim (para mí fue / usr / share / vim / vim80 ).

El segundo comando enumera todos los nombres de tipo de archivo en las dos carpetas donde vim almacena las definiciones de tipo de archivo.

Actualizar

Mejoras sugeridas a los dos comandos de muru que ofrecen:

1)

cd $(vim -Nesc '!echo $VIMRUNTIME' -c qa)

2)

find syntax ftplugin -iname '*.vim' -exec basename -s .vim {} + | sort -u

Intente ver en $ VIMRUNTIME / sintaxis. Use: echo $ VIMRUNTIME para conocer su valor. En mi computadora, $ VIMRUNTIME / syntax era / usr / share / vim / vim81 / syntax. Tiene todos los archivos de sintaxis.

Si tiene un vim con gui, también puede usar el menú Sintaxis para obtener todos los tipos de archivos compatibles.