Detectar SO en Vimscript

¿Puedo recuperar el sistema operativo actual (Windows, Linux, OS X, ...) usando Vimscript puro (sin Python o Perl)?

Quiero habilitar diferentes configuraciones en mi .vimrc (sincronizado) para los diferentes tipos de sistemas operativos que estoy usando.

La mejor manera es usarlo has(), con esta función puede verificar las características de Vim; Características específicas del sistema operativo de :help feature-list:

macunix                 Macintosh version of Vim, using Unix files (OS-X).
unix                    Unix version of Vim.
win32                   Win32 version of Vim (MS-Windows 95 and later, 32 or
                        64 bits)
win32unix               Win32 version of Vim, using Unix files (Cygwin)

Y algunos sistemas más antiguos (semi-obsoletos):

amiga                   Amiga version of Vim.
os2                     OS/2 version of Vim.
win16                   Win16 version of Vim (MS-Windows 3.1).
win64                   Win64 version of Vim (MS-Windows 64 bit).
win95                   Win32 version for MS-Windows 95/98/ME.

Ejemplo:

if has('win32')
    echo "Someone please open the Window(s)!"
endif

Una forma alternativa con más flexibilidad es llamar al externo uname, esto también le permite obtener el número de versión y tal:

let uname = system('uname -a')

Tenga en cuenta que unameno está presente en la mayoría de los sistemas Windows.

En general, es mejor usar la detección de funciones , en lugar de la detección del sistema operativo . Por ejemplo, mediante el uso de una de las funciones en has()o comprobando si existe alguna ruta. La publicación 200_success ' ofrece una buena visión general de eso, así que no repetiré el mismo contenido aquí.

has()suena como una buena idea hasta que lo pruebe en Mac OS X: por defecto /usr/bin/vim, has('unix')es verdadero pero ambos has('macunix')y has('mac')son falsos , mientras que, en la descarga normal de MacVim, los tres son verdaderos si usa la GUI o la TUI.

Entonces, la mejor solución es una combinación de has('winXX')Windows y unameen sistemas similares a Unix. Tenga en cuenta que la salida de unametermina con una nueva línea, por lo que debe limpiarse antes de su uso.

Aquí está el código que he estado usando durante un tiempo, actualizado para win64:

if !exists("g:os")
    if has("win64") || has("win32") || has("win16")
        let g:os = "Windows"
    else
        let g:os = substitute(system('uname'), '\n', '', '')
    endif
endif

Después de eso, puede usar la g:osvariable en cualquier parte de su vimrc:

if has("gui_running")
    if g:os == "Darwin"
        set guifont=Fira\ Mono:h12
    elseif g:os == "Linux"
        set guifont=Fira\ Mono\ 10
    elseif g:os == "Windows"
        set guifont=Fira_Mono:h12:cANSI
    endif
endif

Las variables de entorno serían útiles.

Para detectar tmux, puede verificar if !empty($TMUX)o if $TERM == 'screen'.

También puede deducir el sistema operativo a partir de variables de entorno como $MACHTYPE( que está configurado por Bash ) o $PATH.

Para detectar si está instalada una función como TFS, puede usar la executable()función.

Como otros ya han indicado, una detección confiable puede ser complicada. Mejor no reinventar la rueda, así que me gustaría mencionar la biblioteca vim-misc , que proporciona xolox#misc#os#is_mac()y xolox#misc#os#is_win()funciona.

Lo intenté has('unix'), pero no lo encontré útil, ya que todos mis Linux, Mac y Windows Git Bash volvieron truepor él.

Me pareció unameadecuado, ya que distingue entre Linux, Mac, Windows, sin demasiada granularidad.

let uname = substitute(system('uname'), '\n', '', '')
" Example values: Linux, Darwin, MINGW64_NT-10.0, MINGW32_NT-6.1

if uname == 'Linux' || uname == 'Darwin'
    " do linux/mac command
else " windows
    " do windows command
endif