finalización de la pestaña zsh en línea vacía

12

Me gustaría un tcsh'ism que no he podido encontrar: en una línea en blanco sin contenido, quiero presionar la tecla de tabulación y ver el equivalente de un ls. Es decir que quiero

$ <tab>

para hacer otra cosa y luego darme un \ t. He encontrado recursos fantásticos para completar comandos, pero no para este caso base. ¡Cualquier ayuda con esto sería genial! Gracias.

shell configuration zsh kristopolous
fuente

Respuestas:

8 
# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files
John Eikenberry
fuente
Muy aseado. ¿Sería posible ocultar de alguna manera la lista nuevamente? Tab-to-show y luego tab-to-hide sería bueno.
Parker Coates
Gracias John, encontré tu solución y la
adapté
7

El comportamiento de Tabal principio de una línea está controlado por el estilo . Sin embargo, solo hay dos comportamientos compatibles:insert-tab

  • finalización como de costumbre, bajo zstyle ':completion:*' insert-tab false
  • inserte una pestaña, debajo zstyle ':completion:*' insert-tab true
  • ya sea uno u otro debajo zstyle ':completion:*' insert-tab pending[=N]

Si solo desea completar los comandos en esa posición, zstyle ':completion:*' insert-tab truelo hará. Si desea algo diferente, como enumerar los archivos en el directorio actual, deberá modificarlos _main_complete.

Se discutió un hilo reciente en la lista de trabajadores de zshinsert-tab .

Gilles 'SO- deja de ser malvado'
fuente
¡fantástico! Por _main_complete parece que estás haciendo referencia a algún lugar en el código C? Lamento la tonta pregunta, pero ¿dónde se podría encontrar eso?
1
@ user535759: No, _main_completees parte del código zsh que implementa la finalización. Está Completion/Base/Core/_main_completeen el árbol de origen, normalmente instalado en una ubicación como /usr/share/zsh/functions/Completion/Base/_main_complete.
Gilles 'SO- deja de ser malvado'
@llua Cambiar el estilo asociado a -command-no causa que <Tab> enumere los archivos en el directorio actual. Todo lo que has hecho es restringir las coincidencias para omitir los nombres de los comandos. Pero solo se enumeran las cosas que se completarían en esta posición, por lo que no se incluyen los archivos en el directorio actual (solo directorios y ejecutables dependiendo de autocdy PATH).
Gilles 'SO- deja de ser malvado'
3

Aquí está la implementación completa de la lista automática de tcsh en zsh, cuando presiona tab en la línea vacía

% <TAB>

Aquí está:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

Si desea emular tcsh más de cerca, también agregue esto a su .zshrc:

unsetopt always_last_prompt       # print completion suggestions above prompt
ILUXA
fuente
2

Escribí este widget zsh que mejora el uso de TAB, no solo en una línea vacía, sino también mientras está escribiendo un comando.

  • Enumerará los archivos en una línea de comando vacía y en el medio de cualquier comando.
  • Enumerará los directorios en una línea de comando vacía.
  • Enumerará los ejecutables en una línea de comando vacía.

Se puede configurar para anteponer "cd" o "./" en aquellos casos con una variable global.

export TAB_LIST_FILES_PREFIX

tab_list_files_example

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA
nachoparker
fuente