Error de comando de sintaxis

Un error "La sintaxis del comando es incorrecto" siempre aparece cada vez que ejecuto este archivo por lotes. Parece que no puedo averiguar qué parte de la secuencia de comandos está causando este error. ¿Alguna idea?

rem Process all *.tif files in input path
pushd "%in_path%"
for %%a in (*.tif) do (
   set "fileName=%%a"
   rem If the YearDay in this file is the same of previous one
   if "!fileName:~1,7!" equ "!yearDay!" (
      rem Join this filename to previous list
      set "fileList=!fileList!!fileName! "
      set /A numFiles+=1
   ) else (
      rem Merge the files in the list if there are more than 3, in the out_path leaving only TYYYYDDD.L2_LAC.Tera.tif
      if !numFiles! gtr 3 (
         gdal_merge.py -n 0 -a_nodata -32767 -of GTiff -o %out_path%\T!yearDay!.L2_LAC.Tera.tif !fileList!
         rem Move processed files to a different directory
         set "fileList=!fileList:~0,-1!"
         move !fileList: =,! "%proc_path%"
      )
      rem And start a new YearDay and fileList
      set "yearDay=!fileName:~1,7!"
      set "fileList=!fileName! "
      set numFiles=1
   )
)
popd

Lo descubrí con la ayuda de un amigo. Acabo de reemplazar esta parte de la secuencia de comandos,

 set "fileList=!fileList:~0,-1!"
 move !fileList: =,! "%proc_path%"

con este,

for %%a in (!fileList!) do move %%a "%proc_path%"  >nul