Sumar valores dentro de un marco de tiempo

Tengo 550 filas de datos que representan los tiempos de vuelo diarios. Cada vuelo, dependiendo del tipo de aeronave, requiere un cierto número de personas para asistir al vuelo. Esa tarea lleva 45 minutos. Por lo tanto, en cualquier momento del vuelo, habrá personas ocupadas con ese vuelo más cualquier vuelo dentro de los 45 minutos anteriores. Quiero obtener un recuento agregado del total de personas requeridas en cualquier momento del vuelo. También quiero tratar los 45 minutos como una variable de entrada para ver cómo los cambios en este tiempo de tarea afectan la demanda de mano de obra en cada tiempo de vuelo.

Aquí hay una maqueta de cómo se ven los datos:

     A            B         C.        D
1   2:30          4        0:45       4
2   2:45          3.                  7
3   3:15          2.                  9
4   3:30          4.                  9
5   3:35          5.                 11

La columna A contiene los tiempos de vuelo. La columna B contiene la cantidad de personas requeridas para ese vuelo. La celda C1 contiene el valor para el tiempo de la tarea. Quiero completar la columna D con el recuento agregado de personal requerido en cada tiempo de vuelo. El ejemplo se muestra con los resultados completados.

Un cálculo de muestra se vería así. Use la fila 4 como ejemplo. El tiempo de vuelo es a las 3:30. Basado en un tiempo de tarea de 45 minutos, todos los vuelos en o después de las 2:45 requerirían personas concurrentes. Hay tres vuelos de este tipo, 2:45, 3:15 y 3:30. La dotación de personal de la columna B para esos vuelos es 3, 2 y 4, por lo que el requisito total de dotación de personal en el momento del vuelo 3:30 es 9. Eso es lo que pasa en D4.

Si tuviera que cambiar el tiempo de la tarea en C1 a 30 minutos, solo calificarían los vuelos de 3:15 y 3:30, por lo que el total en D4 sería 6.

Lo he intentado SUMIFy SUMIFS. He agregado una fila con los datos (tiempo) menos y C1luego intenté sumar todo Bentre ese rango de tiempo. Parece que no puedo obtener la Bcolumna para agregar los datos.

Lo intenté

    =sumif(A:A,"<=A4",B:B)-sumif(A:A,"<=A4-C1",B:B)

Aquí hay una solución. Esta es la fórmula para D1. Ingrese y luego copie para otras celdas en D:

    =SUM(INDIRECT("b"&IF(ISNA(MATCH(A1-C$1,A$1:A1,0)),IF(ISNA(MATCH(A1-C$1,A$1:A1,1)),1,MATCH(A1-C$1,A$1:A1,1)+1),MATCH(A1-C$1,A$1:A1,0))):B1)

Esto es básicamente la lógica. Encuentra la primera fila que cumple con sus criterios y luego suma los valores en B entre allí y la fila actual. La forma en que encuentra la primera fila es mediante el uso de la función MATCH para comparar el tiempo en la columna A menos el tiempo en C1 con los valores de tiempo en las filas hasta e incluyendo la fila actual. MATCH no tiene una búsqueda de GE para valores en orden ascendente, por lo que utiliza una combinación de LE y EQ.

• Si no hay nada LT, eso significa que la fila 1 es GE, entonces esa es la primera fila.
• Si una fila es EQ, esa es la fila inicial.
• Si una fila es LE pero no EQ, eso significa que la siguiente fila es la primera GE, entonces esa es la primera fila.