Desactivar o retrasar el efecto Alt + Tab Aero Peek en Windows 7

En Windows 7, presionar Alt+ Tabmuestra el efecto de ventanas transparentes (Aero). El cambio de pantalla me distrae mientras trato de averiguar a qué ventana cambiar en función de la vista previa en miniatura (que es suficiente para mí la mayor parte del tiempo). ¿Hay alguna forma de desactivar el efecto Aero Peek o retrasar su activación a algo así como 6 segundos más o menos?

En la barra de tareas, el efecto Aero Peek se activa a pedido cuando paso el mouse sobre las miniaturas reales. Este comportamiento no es un problema y si tengo una opción, no quiero que se apague.

Puede encontrar vistaswitcher más de su agrado. Proporciona un cuadro de vista previa instantánea en la mitad de la pantalla (configurable), sin hacer que se desvanezca lentamente la transparencia. ¡Intentalo!

No hay forma de deshabilitar adecuadamente el aerodinámico para solo alt-tab, pero puede establecer el retraso en un valor absurdamente alto, deshabilitándolo efectivamente. Hay otra publicación que detalla este proceso. Esencialmente, debe crear el valor DWORD LivePreview_msen HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\AltTabun número muy grande. Esta tecla almacena el tiempo en milisegundos para retrasar, por lo que 60000 debería ser suficiente, ya que dudo que mantenga presionada la tecla alt durante más de un minuto.

Tenga en cuenta que configurar la clave de registro para 0deshabilitar Aero-peek para Alt-Tab por completo. Debe cerrar sesión y volver a iniciarla para que el cambio surta efecto.

Puedes arreglar esto en rendimiento; Tuve el mismo problema. No es "nuestro cerebro tiene problemas", es una usabilidad horrible debido a la hinchazón característica. Alt-tab fue más o menos perfecto en Vista.

Vaya a Ajustar efectos visuales (desde Rendimiento en el Panel de control) y desmarque Aero Peek.

Otro truco que puede hacer es usar la pestaña alternativa "antigua" que está presente en Windows 7:

1. Mantenga presionada la tecla alt izquierda
2. Toque la tecla alt derecha
3. Manteniendo presionada la tecla Alt izquierda, use la tecla de tabulación como lo haría normalmente para recorrer las tareas

Notarás que esto usa el viejo conmutador de estilo alt-tab y no desvanece las ventanas por ti.

Puede que le interese una característica de Windows 7 que sea algo similar a la pestaña alternativa: WinKey + 1, WinKey + 2, WinKey + 3, etc. Estas teclas de acceso rápido activan las ventanas en la barra de tareas en las posiciones 1, 2, 3, etc.

Si fija sus programas de uso frecuente en la barra de tareas, siempre estarán en una determinada "posición de ranura" en la barra de tareas. Debido a esto, será trivialmente fácil memorizar qué WinKey + N se alinea con qué programa. Presionando WinKey + N repetidamente "alt tab" a través de las ventanas abiertas de ese programa. Esto me parece particularmente útil con las ventanas del Explorador de Windows, porque a menudo tengo muchas de ellas abiertas.

Sé que este es un tema bastante antiguo, pero tampoco me gustó la función Areo Peek cuando usé Alt+ TABpara cambiar de tarea. Además, no rechazo completamente Areo Peek; por ejemplo, me gusta echar un vistazo a mi escritorio de Windows con WIN+ Space.

He intentado mucho para desactivar Areo Peek apenas solamente para Alt+ TABcambiar de tarea, pero nada realmente funcionó para mí. Conozco todas las sugerencias de registro, por ejemplo, configurar el retraso Aero Peek en milisegundos a un valor muy alto. Pero esto no funciona, al menos no en todas las máquinas: desde mi experiencia, puede establecer un valor alto que todavía está limitado a 3000 ms internamente (tal vez esto funcionó antes del Service Pack para Windows 7).

Así que decidí ir por otro camino e intentar resolver este problema a través de AutoHotkey . Este script deshabilita Aero Peek solo para Alt+ TAB, y solo para esto, por lo que aún puede usar las otras funciones de Aero Peek.

El script se prueba con la versión de AutoHotkey "AutoHotkey_L 1.1.00.00" con Windows 7 Professional de 64 bits con un usuario de Windows con derechos de administrador, y hasta ahora se informó que funcionaba en todos los sistemas de los que recibí comentarios. Simplemente instale AutoHotkey y configure el archivo de script para que se ejecute automáticamente cuando se inicie Windows. Es muy liviano y utiliza muy pocos recursos y tiempo de CPU.

Lo publico aquí con la esperanza de que esto ayude a cualquiera que tenga este problema. Descargue el script desde:

http://dl.dropbox.com/u/15020526/Privat/Software/GA/AutoHotkey/DisableAeroPeekForAltTab_1.0.zip

; ==============================================================
;
; AVOID "AERO PEEK" FOR ALT-TAB - AUTOHOTKEY-SCRIPT
; 
; Disables Windows 7 Areo Peek feature for ALT-TAB, and only 
; for this, so that other Areo Peek features (like WIN+SPACE) 
; can still be used.
;
; This script can be run with AutoHotkey (http://www.autohotkey.com/),
; tested against Version AutoHotkey_L 1.1.00.00 with Windows 7 
; Professional 64 bit with a Windows user with admin rights.
;
; @author   Timo Rumland <timo.rumland${at}the-cr.de>, 19.09.2011
; @version  1.0
;
; --------------------------------------------------------------
;
; LICENSE
; 
; This software is distributed under the FreeBSD License.
;
; Copyright (c) 2011 Timo Rumland <timo.rumland${at}the-cr.de>. All rights reserved.
; 
; Redistribution and use in source and binary forms, with or without modification, are
; permitted provided that the following conditions are met:
; 
;    1. Redistributions of source code must retain the above copyright notice, this list of
;       conditions and the following disclaimer.
; 
;    2. Redistributions in binary form must reproduce the above copyright notice, this list
;       of conditions and the following disclaimer in the documentation and/or other materials
;       provided with the distribution.
; 
; THIS SOFTWARE IS PROVIDED BY <COPYRIGHT HOLDER> ''AS IS'' AND ANY EXPRESS OR IMPLIED
; WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
; FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL <COPYRIGHT HOLDER> OR
; CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
; SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
; ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
; ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
; 
; The views and conclusions contained in the software and documentation are those of the
; authors and should not be interpreted as representing official policies, either expressed
; or implied, of <copyright holder>.
;
; ==============================================================

#NoEnv
#SingleInstance     force
SendMode            Input 
SetWorkingDir       %A_ScriptDir%
SetTitleMatchMode   2       ; 2: A window's title can contain WinTitle anywhere inside it to be a match. 


; =======
; Global
; =======

    visualEffectsRegistryKey                := Object()
    visualEffectsRegistryKey.valueType      := "REG_DWORD"
    visualEffectsRegistryKey.rootKey        := "HKEY_CURRENT_USER"
    visualEffectsRegistryKey.subKey         := "Software\Microsoft\Windows\CurrentVersion\Explorer\VisualEffects"
    visualEffectsRegistryKey.valueName      := "VisualFXSetting"
    visualEffectsRegistryKey.value          := 3    ; Manual Visual FX Settings

    enableAeroPeekRegistryKey               := Object()
    enableAeroPeekRegistryKey.valueType     := "REG_DWORD"
    enableAeroPeekRegistryKey.rootKey       := "HKEY_CURRENT_USER"
    enableAeroPeekRegistryKey.subKey        := "Software\Microsoft\Windows\DWM"
    enableAeroPeekRegistryKey.valueName     := "EnableAeroPeek"
    enableAeroPeekRegistryKey.enabledValue  := 1
    enableAeroPeekRegistryKey.disabledValue := 0


; ===============
; Initialization
; ===============

    ; Initially write "VisualFXSetting" registry key to "manual settings"
    writeRegistryKey( visualEffectsRegistryKey, visualEffectsRegistryKey.value )


; ========
; Hotkeys
; ========

    ; -----------------------------------------------------------------------------
    ; This is the ALT-TAB hotkey that triggers setting Aero Peek to disabled 
    ; right before Windows displays the ALt-TAB-Menu. After releasing the ALT-key,
    ; Areo Peek will be enabled again.
    ; -----------------------------------------------------------------------------
    ~!Tab::

        writeRegistryKey( enableAeroPeekRegistryKey, enableAeroPeekRegistryKey.disabledValue )
        KeyWait Alt
        writeRegistryKey( enableAeroPeekRegistryKey, enableAeroPeekRegistryKey.enabledValue )

    return


; ==========
; Functions
; ==========

    ; ----------------------------------------------------------------------
    ; Writes the given value to the given registry key. The "registryKey"
    ; is an object with the properties "valueType", "rootKey", "subKey" and
    ; "valueName", suitable to the AHK function "RegWrite".
    ; ----------------------------------------------------------------------
    writeRegistryKey( registryKey, value )
    {
        valueType   := registryKey.valueType
        rootKey     := registryKey.rootKey
        subKey      := registryKey.subKey
        valueName   := registryKey.valueName

        RegWrite %valueType%, %rootKey%, %subKey%, %valueName%, %value%
    }

Puede distribuirlo libremente, bajo la licencia FreeBSD.

Puede desplazar el mouse sobre la vista previa en miniatura en el centro de la pantalla mientras mantiene presionada ALT + Tabulador. A pesar de que las ventanas de fondo siguen apareciendo, el movimiento del mouse centrará su atención en las miniaturas. Encuentro esto menos confuso que presionar repetidamente la pestaña mientras ALT está deprimido. Luego, simplemente haga clic en la ventana que desea mover.

También Win + Tab es menos confuso también. Puede acostumbrarse más rápido que Alt + Tab.

Tenga en cuenta también que puede hacer lo contrario. Hasta ahora hemos sido entrenados para prestar atención a las miniaturas del centro. Pero con el ciclo de la ventana que se ofrece con ALT + TAB, puede entrenarse para comenzar a ignorar las miniaturas centrales y, en cambio, centrar su atención en el ciclo de la ventana. Después de un tiempo, estoy bastante seguro de que te preguntarás por qué esto fue un problema para ti. Todo está en nuestro cerebro :)

Usted PUEDE desactivar Aero Peek por sólo ALT+TAB

La solución es establecer el siguiente valor del Registro que restaura el comportamiento de Windows XP-Style de ALT+ TAB:

1. Ejecute REGEDIT.EXE
2. Navegar a HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer
3. Cree un nuevo valor DWORD nombrado AltTabSettingsy establezca su valor en1
4. El cambio hace efecto inmediatamente.

_{crédito: Esta respuesta de superusuario}

La respuesta vinculada también proporciona un comando de PowerShell que crea el valor anterior:

Set-ItemProperty HKCU:\Software\Microsoft\Windows\CurrentVersion\Explorer AltTabSettings ([int]1)