AppleScript + Quicktime: inicie y detenga una grabación de película y expórtela al disco

Intentando iniciar una grabación de pantalla, espere unos segundos, detenga la grabación y exporte la grabación guardada al disco.

Versiones

• AppleScript 2.2.4
• QuickTime: 10.2

AppleScript

set filePath to "" & (path to desktop)

tell application "QuickTime Player"
    set newMovieRecording to new movie recording
    tell newMovieRecording
        start
        delay 2 --(seconds)
        stop
        export newMovieRecording in (filePath & "movie") using settings preset "25 fps"
    end tell
end tell

Los comandos de parada e inicio funcionan correctamente pero export El comando está fallando con este error:

movie_record.scpt:215:294: execution error: QuickTime Player got an error: Can’t get document "Movie Recording". (-1728)

Encontré una solución. Tenga en cuenta que hay un ligero retraso (aproximadamente ~ 2 segundos) desde el momento en que se invoca el script hasta que comienza realmente la grabación.

(*********************************************
Record a Single `QuickTime` Movie
Args:
    1. name: The name of the movie.
    2. seconds: The length of the movie you want to record in seconds.
Usage:
    > osascript movie_record.scpt 'name' 5
    > osascript movie_record.scpt <file_name> <seconds>
**********************************************)
on run argv
    set movieName to item 1 of argv
    set delaySeconds to item 2 of argv
    set filePath to (path to desktop as text) & movieName
    set f to a reference to file filePath

    tell application "QuickTime Player"
        set newMovieRecording to new movie recording

        tell newMovieRecording
            start
            delay delaySeconds
            pause
            save newMovieRecording in f
            stop
            close newMovieRecording
        end tell
    end tell
end run