¿Configurar VIM para copiar y pegar atajos de teclado desde el búfer del sistema en Ubuntu?

¿Cómo configuro VIM para usar Ctrl- cpara copiar y Ctrl- vpegar desde el búfer del sistema en Ubuntu?

Comportamiento predeterminado en MS Windows: -

Aquí hay un excert del archivo mswin.vim: -

" CTRL-X and SHIFT-Del are Cut
vnoremap <C-X> "+x
vnoremap <S-Del> "+x

" CTRL-C and CTRL-Insert are Copy
vnoremap <C-C> "+y
vnoremap <C-Insert> "+y

" CTRL-V and SHIFT-Insert are Paste
map <C-V>       "+gP
map <S-Insert>      "+gP

cmap <C-V>      <C-R>+
cmap <S-Insert>     <C-R>+

" Pasting blockwise and linewise selections is not possible in Insert and
" Visual mode without the +virtualedit feature.  They are pasted as if they
" were characterwise instead.
" Uses the paste.vim autoload script.

exe 'inoremap <script> <C-V>' paste#paste_cmd['i']
exe 'vnoremap <script> <C-V>' paste#paste_cmd['v']

imap <S-Insert>     <C-V>
vmap <S-Insert>     <C-V>

" Use CTRL-Q to do what CTRL-V used to do
noremap <C-Q>       <C-V>

y el script paste.vim que se requiere para cortar / pegar en modo bloque: -

    " Vim support file to help with paste mappings and menus
" Maintainer:   Bram Moolenaar <[email protected]>
" Last Change:  2006 Jun 23

" Define the string to use for items that are present both in Edit, Popup and
" Toolbar menu.  Also used in mswin.vim and macmap.vim.

" Pasting blockwise and linewise selections is not possible in Insert and
" Visual mode without the +virtualedit feature.  They are pasted as if they
" were characterwise instead.  Add to that some tricks to leave the cursor in
" the right position, also for "gi".
if has("virtualedit")
  let paste#paste_cmd = {'n': ":call paste#Paste()<CR>"}
  let paste#paste_cmd['v'] = '"-c<Esc>' . paste#paste_cmd['n']
  let paste#paste_cmd['i'] = 'x<BS><Esc>' . paste#paste_cmd['n'] . 'gi'

  func! paste#Paste()
    let ove = &ve
    set ve=all
    normal! `^
    if @+ != ''
      normal! "+gP
    endif
    let c = col(".")
    normal! i
    if col(".") < c " compensate for i<ESC> moving the cursor left
      normal! l
    endif
    let &ve = ove
  endfunc
else
  let paste#paste_cmd = {'n': "\"=@+.'xy'<CR>gPFx\"_2x"}
  let paste#paste_cmd['v'] = '"-c<Esc>gix<Esc>' . paste#paste_cmd['n'] . '"_x'
  let paste#paste_cmd['i'] = 'x<Esc>' . paste#paste_cmd['n'] . '"_s'
endi

Esto es mínimo, suponiendo que la mayoría de las cosas son configuraciones predeterminadas **:

:behave mswin
:set clipboard=unnamedplus
:smap <Del> <C-g>"_d
:smap <C-c> <C-g>y
:smap <C-x> <C-g>x
:imap <C-v> <Esc>pi
:smap <C-v> <C-g>p
:smap <Tab> <C-g>1> 
:smap <S-Tab> <C-g>1<

• línea 1: hace que las teclas Mayús + flechas seleccionen texto (y hace más *)

• línea 2: hace que "+ (y" *) sea el registro predeterminado (gui / término portapapeles)

• líneas 3,4,5,6: hace Ctrl-x / c / v Cortar / Copiar y Pegar

• línea 7,8: realiza selecciones de sangría / tabulación TAB / SHIFT + TAB

Precaución: *** [: set] tings puede alterar este comportamiento y que muchos ajustes pueden ser necesarios para satisfacer sus necesidades, como dije, mínimo. * [: behave] cambia muchos [: set] tings leer los documentos.

Mapa Ctrl-V para ejecutar el comando del sistema que toma el portapapeles del sistema y lo arroja a un registro, y lo pega en la pantalla debajo del cursor:

vmap <C-c> y:call system("xclip -i -selection clipboard", getreg("\""))<CR>:call system("xclip -i", getreg("\""))<CR>
nmap <C-v> :call setreg("\"",system("xclip -o -selection clipboard"))<CR>p

Fuente: http://vim.wikia.com/wiki/In_line_copy_and_paste_to_system_clipboard