¿Cómo elimino el botón Actualizar de la barra de herramientas Dirección?

Me gusta poder ejecutar comandos directamente desde mi barra de tareas. Entonces, habilité la barra de herramientas Dirección en mi nuevo sistema Windows 7, tal como lo había hecho en mi antiguo sistema XP. Sin embargo, la barra parece tener una longitud mínima obligatoria (he publicado una pregunta separada al respecto) que es un poco más larga de lo que preferiría. Además, se consume un poco más de espacio horizontal mediante un botón Actualizar al final del mismo.

Este botón Actualizar parece similar al botón Ir que solía mostrarse de forma predeterminada en versiones anteriores. Ese botón se eliminó fácilmente al cambiar un valor de registro que no parece existir en Windows 7. ¿Existe un truco de registro similar que pueda usar para eliminar el nuevo botón Actualizar?

Como dije en su otra pregunta, no hay una forma integrada de modificar la barra de direcciones. Deberá utilizar un programa de terceros que se ejecute en segundo plano y modifique las propiedades de la barra de direcciones para ajustar su longitud y ocultar el botón de actualización.

Desafortunadamente, no conozco ninguno de esos programas, ni puedo encontrar ninguno. Tengo una herramienta que escribí yo mismo que es similar a WinSpy ++ , pero aunque tanto mi programa como WinSpy ++ se pueden usar para alterar la longitud y ocultar el botón manualmente, ninguno de los dos se ejecuta en segundo plano para detectar cada vez que se crea y ejecuta la barra de direcciones. Las modificaciones automáticamente.

Una cosa que podría intentar es usar un tipo de programa de teclas de acceso rápido / macro que le permita establecer desencadenantes para realizar eventos, y establecer un desencadenador para que sea window created - address-bar...y establecer el evento para que sea hide refresh button; set address-bar length=...probable que esto también se pueda lograr con AutoHotkey o AutoIt.

Este es el puerto AutoHotKey de mi programa C ++ para eliminar el botón de actualización. (Se puede compilar y ejecutar en segundo plano).

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; NoAddressBarButton.ahk (http://superuser.com/questions/444406/)
;
; This script hides the refresh button of the address-bar band of the Windows 7
; taskbar. It also extends the combo-box (edit field) to use the space of the
; refresh button.
;
;   (cl) 2012- Synetech inc., Alec Soroudi
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

#NoTrayIcon                                       ;No tray icon, duh
#NoEnv                                            ;Not using environment vars
#SingleInstance Force                             ;Use only a single instance
#Persistent                                       ;Using a timer loop; keep open

SetTimer, Run, 1000                               ;Re-run the check every second

Run:
IfWinExist ahk_class Shell_TrayWnd                ;Check if taskbar exists
{
  ControlGet, tv, Visible, ,  ToolbarWindow323    ;Is refresh button visible?
  ControlGetPos, tx,ty,tw,th, ToolbarWindow323    ;Get button width
  ControlGetPos, cx,cy,cw,ch, ComboBoxEx321       ;Get combobox width
  ControlGetPos, mx,my,mw,mh, msctls_progress321  ;Get address-bar width
  if ((tv==1) || (cw<mw))                         ;If button visible
                                                  ;or resized (combobox is short)
  {
    Control, Hide,, ToolbarWindow323              ;(Re-)hide the refresh button
    ControlGetPos, cx,cy,cw,ch, ComboBoxEx321     ;Get current combobox width
    cw:=cw+tw                                     ;Add the button width
    ControlMove, ComboBoxEx321, , , %cw% ,        ;Extend combobox to include button
  }
}