¿Cómo cambio el idioma de todas las diapositivas de PowerPoint a la vez?

Aunque este hilo es bastante antiguo, Microsoft no ha proporcionado ninguna solución que yo sepa. Sugiero otro enfoque para los usuarios de Mac: abra su presentación en Keynote, cambie el lenguaje ortográfico y posiblemente edite toda su presentación, luego expórtela a PowerPoint.

Para cambiar fácilmente el idioma de todo el PowerPoint, abra la pestaña Ver y seleccione la vista Esquema .

Ahora presiona

• Ctrl+ Apara seleccionar todo.
• Herramientas → Idioma → Elija su idioma para configurar.

Del mismo modo, mientras tiene todo seleccionado, puede cambiar otras cosas, como fuentes, colores, etc. Aunque, por supuesto, en muchos casos esto se hace mejor cambiando el patrón de diapositivas, una presentación que ha tenido muchos editores puede tener muchos conjuntos de formatos 'duros' que se desvía del maestro subyacente y necesita restablecerse para ser coherente. También puede restablecer diapositivas individuales al estilo maestro, pero esto puede provocar que los marcadores de posición también se muevan, lo que puede ser indeseable en algunas situaciones.

PowerPoint 2013

• Ver → Esquema → seleccionar todas las diapositivas (en un menú de la izquierda) mediante Ctrl+ A.
• Revisar → Idioma → Establecer idioma de corrección ... → Elija su idioma para configurar.

En cuanto a mí, se necesitaba reiniciar PowerPoint . Probablemente porque también cambié el Idioma de edición :

• Revisar → Idioma → Establecer idioma de corrección ... → Preferencias de idioma → Elegir idiomas de edición .

Usando Powerpoint 2010 abrí el menú Esquema -

Seleccioné todo el texto (Ctrl + A), abrí el menú de idioma y configuré mi idioma de prueba

¡Y funcionó!

El menú de idioma se encuentra en la pestaña Revisar cinta (después de la pestaña Presentación de diapositivas y no está visible en la captura de pantalla).

Las respuestas existentes funcionan para el texto que está presente en el esquema. Desafortunadamente, en mi caso, esto no cubrió una parte significativa del texto, incluidas figuras, tablas, etc.

Esta macro resolvió el problema para mí:

 Sub ChangeProofingLanguageToEnglish()
    Dim j, k, m, scount, fcount, gcount As Integer
    scount = ActivePresentation.Slides.Count
    For j = 1 To scount
        fcount = ActivePresentation.Slides(j).Shapes.Count
        For k = 1 To fcount
            If ActivePresentation.Slides(j).Shapes(k).HasTextFrame Then
                ActivePresentation.Slides(j).Shapes(k) _
                .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
            If ActivePresentation.Slides(j).Shapes(k).Type = msoGroup Then
                gcount = ActivePresentation.Slides(j).Shapes(k).GroupItems.Count
                For m = 1 To gcount
                    If ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m).HasTextFrame Then
                    ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m) _
                    .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
                Next m
            End If
        Next k
    Next j
End Sub

El "msoLanguageIDEnglishUS" que se usa en la macro anterior se puede reemplazar por cualquier idioma deseado. La lista completa de idiomas se puede encontrar en este artículo

(El crédito es para Ganesh Kumar, quien publicó la macro original aquí . Agregué soporte para el primer nivel de agrupación de formas. Para mejorarlo aún más, la macro puede hacerse recursiva para buscar grupos que contengan otros grupos, etc.)

Creo que he mejorado en la respuesta de Iñigo para proporcionar una versión recursiva que cambia todos los artículos al idioma deseado.

Esta versión investigará de forma recursiva cada forma que sea un tipo de grupo. Algunos experimentos sugieren eso msoGroupy msoSmartArtson los tipos de grupo: siéntase libre de agregar a esa lista si encuentra otros tipos de formas que pueden contener objetos de texto.

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Basado en las respuestas de Inigo, Duncan, Maria y DomDev, esto funciona para formas, tablas, grupos, SmartArt, ahora y en el futuro:

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

La versión de Duncan funciona bien para todo menos para tablas. Encontré otro código que parece funcionar también con tablas: https://stackoverflow.com/questions/4735765/powerpoint-2007-set-language-on-tables-charts-etc-that-contains-text

Public Sub changeLanguage()
    On Error Resume Next
    Dim gi As GroupShapes '<-this was added. used below
    'lang = "English"
    lang = "Norwegian"
    'Determine language selected
    If lang = "English" Then
        lang = msoLanguageIDEnglishUK
    ElseIf lang = "Norwegian" Then
        lang = msoLanguageIDNorwegianBokmol
    End If
    'Set default language in application
    ActivePresentation.DefaultLanguageID = lang

    'Set language in each textbox in each slide
    For Each oSlide In ActivePresentation.Slides
        Dim oShape As Shape
        For Each oShape In oSlide.Shapes
            'Check first if it is a table
            If oShape.HasTable Then
                For r = 1 To oShape.Table.Rows.Count
                    For c = 1 To oShape.Table.Columns.Count
                    oShape.Table.Cell(r, c).Shape.TextFrame.TextRange.LanguageID = lang
                    Next
                Next
            Else
                Set gi = oShape.GroupItems
                'Check if it is a group of shapes
                If Not gi Is Nothing Then
                    If oShape.GroupItems.Count > 0 Then
                        For i = 0 To oShape.GroupItems.Count - 1
                            oShape.GroupItems(i).TextFrame.TextRange.LanguageID = lang
                        Next
                    End If
                'it's none of the above, it's just a simple shape, change the language ID
                Else
                    oShape.TextFrame.TextRange.LanguageID = lang
                End If
            End If
        Next
    Next End Sub

Además de la respuesta proporcionada por Mastergalen y para abordar los comentarios sobre el nuevo texto escrito:

Si observa que el idioma cambiará automáticamente cada vez que comience a escribir texto nuevo (lo cual es muy molesto), debe cambiar el idioma predeterminado actual para PowerPoint:

• asegúrese de que la ventana de PowerPoint sea una ventana activa
• en el Windows Taskbar(sí, en realidad no en PowerPoint), verifique si Language barestá visible,
  • Si no va a Control Panel > Region and Language > Keyboards and Languages. Haga clic Change keybords..., cambie a la Language barpestaña y marque la Docked in the taskbaropción. (Esto es de Win7, por lo que podría ser un poco diferente en otras versiones).
• ahora acción clave: en la Language barbarra de tareas, haga clic en el código de idioma y cambie a EN (si actualmente quiere usar inglés en PowerPoint). De ahora en adelante, todo el texto nuevo en PowerPoint estará en el idioma seleccionado :-)
• si desea escribir en su idioma original, simplemente cámbielo de nuevo.

Hice un complemento en 2014 para mí, que todavía funciona bien en PowerPoint 2016. https://github.com/wobba/officeaddin/releases/tag/v1.0.1

Analiza los idiomas usados ​​y le permite cambiarlos todos a la vez, en bucle.