¿Cómo extraer una lista completa de tipos de extensión dentro de un directorio?

Dentro de un directorio, y recursivamente dentro de sus subdirectorios, lo que significa que cada directorio dentro de un directorio es procesado, ¿cómo compilo una lista completa de extensiones únicas dentro del directorio?

El sistema operativo es Windows XP con todas las actualizaciones actuales, pero estoy de acuerdo con ejecutar el script si puedo decir lo que está haciendo, aunque preferiría no tener que instalar dot-net, ya que realmente no me gusta.

Este script por lotes lo hará.

@echo off

set target=%~1
if "%target%"=="" set target=%cd%

setlocal EnableDelayedExpansion

set LF=^


rem Previous two lines deliberately left blank for LF to work.

for /f "tokens=*" %%i in ('dir /b /s /a:-d "%target%"') do (
    set ext=%%~xi
    if "!ext!"=="" set ext=FileWithNoExtension
    echo !extlist! | find "!ext!:" > nul
    if not !ERRORLEVEL! == 0 set extlist=!extlist!!ext!:
)

echo %extlist::=!LF!%

endlocal

Guárdelo como cualquier .batarchivo y ejecútelo con el comando batchfile(sustituya el nombre que haya nombrado) para enumerar el directorio actual o especifique una ruta con batchfile "path". Buscará todos los subdirectorios.

Si desea exportar a un archivo, use batchfile >filename.txt(o batchfile "path" >filename.txt).

Explicación

Todo antes de la for /f...línea simplemente configura las cosas: hace que el directorio de destino busque, habilita la expansión retardada, lo que me permite actualizar las variables en el bucle y define una nueva línea ( LF) que puedo usar para una salida más ordenada. Ah, y los %~1medios "obtienen el primer argumento, eliminando comillas" que evitan las comillas duplicadas, ver for /?.

El bucle usa ese dir /b /s /a:-d "%target%"comando, capturando una lista de todos los archivos en todos los subdirectorios bajo el objetivo.

%%~xiextrae la extensión de las rutas completas que dirdevuelve el comando.

Una extensión vacía se reemplaza con "FileWithNoExtension", para que sepa que existe dicho archivo; si agregué una línea vacía, no es tan obvio.

La lista actual completa si se envía a través de un findcomando, para garantizar la unicidad. La salida de texto del comando find se envía nul, esencialmente a un agujero negro, no lo queremos. Como siempre agregamos un :al final de la lista, también debemos asegurarnos de que la consulta de búsqueda finalice con un :para que no coincida con los resultados parciales; vea los comentarios.

El findcomando establece% ERRORLEVEL% , un valor de 0 indica que hubo una coincidencia. Entonces, si no es 0, la extensión actual no está en la lista hasta el momento y debe agregarse.

La línea de eco básicamente sale, y también reemplazo mis marcadores de posición ( :) con nuevas líneas para que se vea bien.

Aunque no cumpla estrictamente los requisitos para un script por lotes, he usado un script de PowerShell de una sola línea:

Get-Childitem C:\MyDirectory -Recurse | WHERE { -NOT $_.PSIsContainer } | Group Extension -NoElement | Sort Count -Desc > FileExtensions.txt

Potencialmente podría ejecutarlo desde la línea de comando / archivo por lotes:

Powershell -Command "& Get-Childitem C:\MyDirectory -Recurse | WHERE { -NOT $_.PSIsContainer } | Group Extension -NoElement | Sort Count -Desc > FileExtensions.txt"

No reclamo ningún crédito por ello y, por supuesto, necesitará instalar Powershell. Para las versiones más nuevas de Windows, no hay forma de evitar esto.

Si lo elimina C:\MyDirectory, se ejecutará en el directorio actual.

Al final producirá un FileExtensions.txt que contiene algo como lo siguiente:

+-------+------+
| Count | Name |
+-------+------+
| ----- | ---- |
| 8216  | .xml |
| 4854  | .png |
| 4378  | .dll |
| 3565  | .htm |
| ...   | ...  |
+-------+------+

Dependiendo de la estructura de su carpeta, ocasionalmente puede recibir errores que le notifican que tiene una ruta larga.

Get-ChildItem : The specified path, file name, or both are too long. The fully qualified file name must be less than 260 characters, and the directory name must be less than 248 characters.

Cualquier subdirectorio allí tampoco se analizará, pero los resultados de todo lo demás aún se mostrarán.

Aquí hay una respuesta detallada usando PowerShell (con Windows XP tendrá que instalar PowerShell):

¡Hola, guionista! ¿Cómo puedo usar Windows PowerShell para elegir las extensiones de archivo únicas utilizadas en una colección de archivos?

Para enumerar todas las extensiones únicas de cmd bajo la ruta que está usando:

Powershell -Command "Get-ChildItem . -Include *.* -Recurse | Select-Object Extension | Sort-Object -Property Extension -Unique"

Me pareció útil cambiar

if "!ext!"=="" set ext=FileWithNoExtension

a

if "!ext!"=="" set ext=.FileWithNoExtension

y para cambiar

echo %extlist::=!LF!%

a

echo %extlist::=!LF!% > ext-list.txt

El archivo generado contenía (sin saltos de línea, pero no importa) .bat.pdf.skp.ai.png.jpg.tif.pcp.txt.lst.ttf.dfont.psd.indd.docx.PDF.JPG.gif.jpeg .dwg.exr.FileWithNoExtension.vrlmap.sat.bak.ctb

que pude usar para mi proyecto.