¿Qué fórmula devolverá un código designado para el valor más alto en un conjunto de celdas? [cerrado]

Quiero devolver el valor más alto en un conjunto de celdas con un código representativo. Una imagen vale más que mil palabras, así que he agregado una para ti a continuación:

Lo que ves en la imagen (columna T, donde la letra se relaciona con uno de los encabezados y muestra cuál es el valor más alto de las tres columnas anteriores) se hizo a mano. No quiero hacer eso por el resto porque tomaría mucho tiempo.

¿Cuál es la fórmula más simple y fácil para lograr esto para alguien que usa Excel 2007? (Si pudiera agregar un poco de explicación con su fórmula, sería aún mejor, pero no necesario).

Como no especificó qué sucede en un empate, voy a suponer que el resultado debería ser NBT si hay un empate en las tres columnas.

1. Encuentra el valor máximo:

   Usa esta fórmula:

   =MAX(Q2:S2)
   

   Esto da el valor máximo. (Esto supone que es para usar en T2)

   Use el administrador de nombres para dar a esta fórmula el nombre MaxV o simplemente use la fórmula misma.

2. Primero SI:

   =IF(Q2=MaxV,"N","")
   

   Este IF () imprime una N o nada

3. Haga una fórmula para otras columnas y combine en una sola ecuación:

   =IF(Q2=MaxV,"N","") & IF(R2=MaxV,"B","") & IF(S2=MaxV,"T","")
   

Si no desea utilizar el administrador de nombres, la fórmula completa es:

=IF(Q2=MAX(Q2:S2),"N","") & IF(R2=MAX(Q2:S2),"B","") & IF(S2=MAX(Q2:S2),"T","")

El &se usa para unir dos letras juntas de forma similar a cómo se usa un + para agregar dos números.

La respuesta de bvaughn es agradable, limpia y simple, especialmente si solo tiene unas pocas columnas. También es intuitivamente escalable si agrega más columnas. Sin embargo, si tiene muchas columnas, ese enfoque puede comenzar a ser difícil de manejar.

Aquí hay un enfoque diferente que se escala mejor si alguna vez tiene que expandir el problema con más columnas.

=CHOOSE(MATCH(MAX(Q2:S2),Q2:S2,0),"N","B","T")

Explicación, trabajando de adentro hacia afuera:

• MAX(Q2:S2) identifica el valor máximo en el rango.

• MATCH(MAX(Q2:S2),Q2:S2,0) localiza ese valor en el rango, dándole un número de posición.

• CHOOSE(position,"N","B","T") selecciona de la lista de valores de salida usando esa misma posición relativa.

Este tipo de fórmula puede manejar una gran cantidad de columnas simplemente agregando los resultados a la lista (y ajustando el rango, por supuesto). La porción del caballo de batalla no cambia cuando las columnas crecen. La fórmula se mantiene compacta porque lo único que crece a medida que agrega columnas es la lista de valores de salida.

Solución alternativa

La función ELEGIR solo es necesaria porque está utilizando etiquetas diferentes de los encabezados de columna. Si usa los encabezados de columna ("Noticias", "Libros", "Tweets" en este caso), puede usar una fórmula genérica que solo haga referencia a los rangos:

=INDEX(Q$1:S$1,1,MATCH(MAX(Q2:S2),Q2:S2,0))

La ubicación de la posición del número más alto es la misma que antes, pero se usa para seleccionar de los encabezados en la primera fila usando ÍNDICE. Esta fórmula permanecería igual para cualquier número de columnas, solo especificando el rango.