¿Exportar una hoja de cálculo de Excel a un archivo de texto de ancho fijo?

Excel tiene la funcionalidad de importar archivos de texto de ancho fijo donde presenta un cuadro de diálogo que le permite elegir dónde se colocan las columnas al principio y al final de los campos.

¿También tiene una funcionalidad donde, dada una hoja de cálculo existente, puede exportar a un archivo de texto de ancho fijo?

Si es así, ¿cómo accedo a esto? Intenté usar Guardar como y elegir Archivo de texto, pero parece que solo se guarda como delimitado por tabulaciones, lo que no me ayuda.

Esto es Excel 2003 si es importante.

Creo que lo más cercano que puede obtener de la funcionalidad nativa de Excel es Guardar como | Texto con formato (delimitado por espacios) (* .prn) . Determinará automáticamente los anchos e insertará espacios para rellenar ese ancho según sea necesario.

Más allá de eso, debe tener una macro u otro complemento que le permita hacer más.

Si tiene Office Professional, puede abrir su archivo de Excel en Access y luego Exportar desde Access. Access le permitirá especificar un diseño de ancho fijo para su archivo exportado, y le brinda controles extremadamente granulares para especificar esos anchos.

Wow, yo mismo iba a hacer esta pregunta pero ya estaba hecha. Toda la salida del portapapeles de Excel está tabdelimitada de manera predeterminada. Esto es un poco molesto para la salida de texto sin formato "real" cuando tiene una fuente de ancho fijo pero no necesariamente admite delimitador de tabulación.

De todos modos, encontré y modifiqué una pequeña macro de Excel que copiará la región actualmente seleccionada como una simple tabla ASCII de columnas de ancho fijo, de esta manera:

187712 201 37 0,18   
2525 580 149 0,25   
136829 137 43 0.31   

Aquí está el código de macro. Para usarlo, asegúrese de habilitar la pestaña Desarrollador en Opciones de Excel si está usando Excel 2007 o posterior.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)

    Dim temp As Integer
    Dim cellsize As Integer
    cellsize = 0
    For c = 1 To selectedcols
        temp = Len(CStr(Cells(1, c)))
        If temp > cellsize Then
            cellsize = temp
        End If
    Next c
    cellsize = cellsize + 1

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(selectedcols * cellsize)
        For c = 1 To selectedcols
            Mid(line, c * cellsize - cellsize + 1, cellsize) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

Primero, formatee sus datos como Courier New (o alguna otra fuente de ancho fijo). Luego guarde como .prn y obtendrá un ancho fijo verdadero.

Ampliando la respuesta de Jeff Atwood, ya que no me dejaba comentar allí:

Modifiqué su macro para establecer el ancho de la columna en la celda más ancha de esa columna y para que cada columna tenga su propio ancho. Su macro solo encontró la celda más ancha en la primera fila y luego estableció el ancho de todas las columnas.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long, linesize As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)
    ReDim CellSizes(1 To selectedcols, 2) As Integer

    Dim temp As Integer
    Dim cellsize As Integer
    linesize = 0
    For c = 1 To selectedcols
        cellsize = 0
        For r = 1 To selectedrows
            temp = Len(CStr(Cells(r, c)))
            If temp > cellsize Then
                cellsize = temp
            End If
        Next
        CellSizes(c, 0) = cellsize + 1
        CellSizes(c, 1) = linesize
        linesize = linesize + cellsize + 1
    Next c

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(linesize)
        For c = 1 To selectedcols
            Mid(line, CellSizes(c, 1) + 1, CellSizes(c, 0)) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

Esto es un asesino para mí. Tiene algunas opciones también.

http://www.sensefulsolutions.com/2010/10/format-text-as-table.html

Funciona con Access fuera de la caja: https://support.office.com/en-ie/article/export-data-to-a-text-file-f72dfc38-a8a0-4c5b-8c2c-bf2950814140#bmsteps con esto de la manera que lo manejé bastante fácil y rápido, mejor que con Excel. En mi caso fue una conversión de la tabla.