Activación silenciosa de Office 2010 después de una instalación desatendida

He creado una instalación desatendida de Office 2010 usando la OCT. Estamos utilizando un MAK en lugar de KMS (no es mi decisión). ¿Hay alguna forma de activar Office 2010 después de la instalación? Aunque la clave se configura durante la instalación, no se activa.

No quiero que se les solicite a los usuarios que se activen, ya que esto será en un entorno de laboratorio.

En caso de que alguien se lo pregunte, Office instala OSPP.VBS en el directorio office14 y puede manejar la activación de Office, entre otras cosas.

En OCT lo configuré para ejecutarse c:\windows\system32\cscript C:\"Program Files (x86)\Microsoft Office\Office14\OSPP.VBS" /actdurante la instalación posterior.

Todos los productos de oficina se activan después de eso. Tengo que instalar silenciosamente Visio, Project y luego Office y hacer que Office inicie la activación y los tres productos se activen a la vez.

No para enturbiar las aguas en esta publicación, pero configuré esto usando este comando en OCT:
[WindowsFolder] \ system32 \ cscript [INSTALLLOCATION] \ OSPP.VBS
con el parámetro de / act

Por si alguien más necesita esa información. Ross

Simplemente arroje este lote en su script sysprep posterior, debería hacer el truco por usted. Probado trabajando en sistemas de 32 bits y 64 bits, así como en diferentes sistemas operativos.

Tal vez alguien pueda vbs este o lo que sea.

activeproper.cmd

REM CUSTOMER NAME HERE
REM DATE LAST MODIFIED

set _win7vlk=XXXXX-8FFQX-YYYYY-33XHT-ZZZZZ
set _2010vlk=YYYYY-YYYYY-WQGB6-KW8P8-XXXXX

REM Use current working dir
cd /d "%~dp0"

if not defined _win7vlk if not defined _2010vlk goto :nokey

echo Checking for internet connectivity needed to activate
echo This screen will not progress until internet is established
echo If you are using firewall please disable the firewall temporarily

:LOOP
PING -n 3 google.com|find "TTL" >NUL
IF NOT ERRORLEVEL 1 goto :ENDLOOP
IF     ERRORLEVEL 1 goto :LOOP
:ENDLOOP
echo Internet Detected

echo Change the time
net time \\LANMACHINEWITHCORRECTTIME /set /y

echo Prompt to activate Windows 7 if needed
if exist "%windir%\system32\slmgr.vbs" FOR /F "tokens=5" %%a in ('cscript "%windir%\system32\slmgr.vbs" -xpr') do (set _act=%%a)
if "%_act%" neq "activated." if defined _win7vlk (
    cscript "%windir%\system32\slmgr.vbs" -ipk %_win7vlk%
    cscript "%windir%\system32\slmgr.vbs" -ato
    )

echo Prompt to activate Office 2010 if needed
if exist "%PROGRAMFILES%\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES%
if exist "%PROGRAMFILES% (x86)\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES% (x86)

if defined _offver if defined _2010vlk (FOR /F "tokens=3* delims=: " %%a in ('cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /dstatus') do (
    if "%%a" == "---OOB_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---OOT_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---NOTIFICATIONS---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    ))



:nokey

También puede activar Office 2010 al momento de instalar una clave MAK configurando el valor de la propiedad AUTO_ACTIVATE. Para hacer esto, siga estos pasos :

1. En la OCT, seleccione Modificar propiedades de configuración en el panel izquierdo y luego haga clic en Agregar en el panel derecho.

2. En el cuadro de diálogo Agregar valor de propiedad , en el cuadro Nombre , escriba AUTO_ACTIVATE . Tenga en cuenta que los nombres de propiedad deben estar en mayúsculas.

3. En el cuadro Valor , escriba 1 y luego haga clic en Aceptar .