CMake: imprima todas las variables accesibles en un script

Me pregunto si hay una manera de imprimir todas las variables accesibles en CMake. No estoy interesado en las variables CMake, como en la --help-variablesopción. Estoy hablando de mis variables que definí, o las variables definidas por los scripts incluidos.

Actualmente estoy incluyendo:

INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityCXX.cmake)

Y esperaba poder imprimir todas las variables que están aquí, en lugar de tener que revisar todos los archivos y leer lo que estaba disponible; puedo encontrar algunas variables que no conocía que pueden ser útiles. Sería bueno ayudar al aprendizaje y al descubrimiento. Es estrictamente para depuración / desarrollo.

Esto es similar a la pregunta en Imprimir todas las variables locales accesibles al alcance actual en Lua , pero para CMake!

¿Alguien ha hecho esto?

Usando la get_cmake_propertyfunción, el siguiente ciclo imprimirá todas las variables CMake definidas y sus valores:

get_cmake_property(_variableNames VARIABLES)
list (SORT _variableNames)
foreach (_variableName ${_variableNames})
    message(STATUS "${_variableName}=${${_variableName}}")
endforeach()

Esto también se puede incrustar en una función conveniente que opcionalmente puede usar una expresión regular para imprimir solo un subconjunto de variables con nombres coincidentes

function(dump_cmake_variables)
    get_cmake_property(_variableNames VARIABLES)
    list (SORT _variableNames)
    foreach (_variableName ${_variableNames})
        if (ARGV0)
            unset(MATCHED)
            string(REGEX MATCH ${ARGV0} MATCHED ${_variableName})
            if (NOT MATCHED)
                continue()
            endif()
        endif()
        message(STATUS "${_variableName}=${${_variableName}}")
    endforeach()
endfunction()

Para imprimir variables de entorno, use el modo de comando de CMake :

execute_process(COMMAND "${CMAKE_COMMAND}" "-E" "environment")

Otra forma es simplemente usar:

cmake -LAH

Desde la página del manual :

-L[A][H]

Lista de variables en caché no avanzadas.

La lista de variables de caché ejecutará CMake y enumerará todas las variables de la caché de CMake que no están marcadas como INTERNALo ADVANCED. Esto mostrará efectivamente la configuración actual de CMake [...].

Si Ase especifica, mostrará también las variables avanzadas.

Si Hse especifica, también mostrará ayuda para cada variable.

ccmakees una buena opción interactiva para inspeccionar interactivamente las variables en caché ( option(o set( CACHE:

sudo apt-get install cmake-curses-gui
mkdir build
cd build
cmake ..
ccmake ..