Soy un principiante en CMAKE. A continuación se muestra un archivo cmake simple que funciona bien en las ventanas del entorno mingw. El problema es claramente con la target_link_libraries()función de CMAKE donde estoy vinculando libwsock32.a. En Windows esto funciona y obtengo los resultados.

Sin embargo, como se esperaba, en Linux, /usr/bin/ldbuscará -lwsock32cuál NO está en el sistema operativo Linux.

Mi problema es: ¿Cómo le indico a CMAKE que evite vincular la biblioteca wsock32 en el sistema operativo Linux?

Cualquier ayuda será apreciada.

Mi archivo CMake simple:

 PROJECT(biourl)
 set (${PROJECT_NAME}_headers ./BioSocketAddress.h  ./BioSocketBase.h ./BioSocketBuffer.h ./BioSocketCommon.h  ./BioSocketListener.h  ./BioSocketPrivate.h  ./BioSocketStream.h ./BioUrl.h BioDatabase.h )

set (${PROJECT_NAME}_sources BioSocketAddress.C  BioSocketBase.C  BioSocketCommon.C BioSocketStream.C  BioUrl.C BioDatabase.C )

add_library(${PROJECT_NAME} STATIC ${${PROJECT_NAME}_headers} ${${PROJECT_NAME}_sources} )

# linkers
#find_library(ws NAMES wsock32 PATHS ${PROJECT_SOURCE_DIR} NO_SYSTEM_ENVIRONMENT_PATH NO_DEFAULT_PATH)

target_link_libraries(${PROJECT_NAME} bioutils wsock32)

install (TARGETS ${PROJECT_NAME}
       RUNTIME DESTINATION bin
       LIBRARY DESTINATION lib
       ARCHIVE DESTINATION lib/archive )

Utilizar

if (WIN32)
    #do something
endif (WIN32)

o

if (UNIX)
    #do something
endif (UNIX)

o

if (MSVC)
    #do something
endif (MSVC)

o similar

consulte Variables útiles de CMake y Plataforma de comprobación de CMake

Dado que este es un problema tan común, geronto-post:

    if(UNIX AND NOT APPLE)
        set(LINUX TRUE)
    endif()

    # if(NOT LINUX) should work, too, if you need that
    if(LINUX) 
        message(STATUS ">>> Linux")
        # linux stuff here
    else()
        message(STATUS ">>> Not Linux")
        # stuff that should happen not on Linux 
    endif()

CMake documentos de lógica booleana

Nombres de plataformas de CMake, etc.

En general

Puede detectar y especificar variables para varios sistemas operativos como ese:

Detectar Microsoft Windows

if(WIN32)
    # for Windows operating system in general
endif()

O:

if(MSVC OR MSYS OR MINGW)
    # for detecting Windows compilers
endif()

Detectar Apple MacOS

if(APPLE)
    # for MacOS X or iOS, watchOS, tvOS (since 3.10.3)
endif()

Detecta Unix y Linux

if(UNIX AND NOT APPLE)
    # for Linux, BSD, Solaris, Minix
endif()

Su problema específico del vinculador

Para resolver su problema con la wsock32biblioteca específica de Windows , simplemente elimínela de otros sistemas, así:

if(WIN32)
    target_link_libraries(${PROJECT_NAME} bioutils wsock32)
else
    target_link_libraries(${PROJECT_NAME} bioutils)
endif()

Tienes algunas palabras especiales de CMAKE, échale un vistazo:

if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
    // do something for Linux
else
    // do something for other OS

Las expresiones generadoras también son posibles:

target_link_libraries(
    target_name
    PUBLIC
        libA
        $<$<PLATFORM_ID:Windows>:wsock32>
    PRIVATE
        $<$<PLATFORM_ID:Linux>:libB>
        libC
)

Esto vinculará libA, wsock32 y libC en Windows y vinculará libA, libB y libC en Linux

Expresiones del generador de CMake

Trata eso:

if(WIN32)
    set(ADDITIONAL_LIBRARIES wsock32)
else()
    set(ADDITIONAL_LIBRARIES "")
endif()

target_link_libraries(${PROJECT_NAME} bioutils ${ADDITIONAL_LIBRARIES})

Puede encontrar otras variables útiles aquí .

Quiero dejar esto aquí porque tuve problemas con esto al compilar para Android en Windows con el SDK de Android.

CMake distingue entre plataforma TARGET y HOST.

Mi OBJETIVO era Android, por lo que las variables como CMAKE_SYSTEM_NAME tenían el valor "Android" y la variable WIN32 de la otra respuesta aquí no estaba definida. Pero quería saber si mi sistema HOST era Windows porque necesitaba hacer algunas cosas de manera diferente al compilar en Windows, Linux o IO. Para hacer eso, utilicé CMAKE_HOST_SYSTEM_NAME que encontré que apenas se conoce o se menciona en ninguna parte porque para la mayoría de las personas TARGEt y HOST son lo mismo o no les importa.

Espero que esto ayude a alguien en algún lugar ...

Use alguna macro de preprocesador para verificar si está en Windows o Linux. Por ejemplo

#ifdef WIN32
LIB= 
#elif __GNUC__
LIB=wsock32
#endif

incluya -l $ (LIB) en su comando de compilación.

También puede especificar algún argumento de línea de comando para diferenciar ambos.