¿Cómo convertir std :: string a NSString?

Hola, estoy tratando de convertir un estándar std::stringen uno, NSStringpero no tengo mucha suerte.

Puedo convertir con éxito de an NSStringa a std::stringcon el siguiente código

NSString *realm = @"Hollywood";
std::string REALM = [realm cStringUsingEncoding:[NSString defaultCStringEncoding]];

Sin embargo, obtengo un error de tiempo de compilación cuando intento lo siguiente

NSString *errorMessage = [NSString stringWithCString:REALM encoding:[NSString defaultCStringEncoding]];

El error que obtengo es

Cannot convert 'std::string' to 'const char*' in argument passing

¿Me estoy perdiendo de algo?

Gracias por adelantado.

Obtenga c-string de std :: string para la conversión:

NSString *errorMessage = [NSString stringWithCString:REALM.c_str() 
                                   encoding:[NSString defaultCStringEncoding]];

En primer lugar, debe utilizar Objective-C ++ para que esto funcione en lo más mínimo; La forma más sencilla de asegurarse de que es cambiar el nombre de todos sus *.marchivos a*.mm

Con mucho, la forma manual más utilizable (no obsoleta) de introducir un C ++ std::stringen un NSStringes con:

std::string param; // <-- input
NSString* result = [NSString stringWithUTF8String:param.c_str()];
NSString* alternative = [[NSString alloc] initWithUTF8String:param.c_str()];

Esto funcionará en la mayoría de los casos, y si no está haciendo una detección y conversión de codificación específica, UTF-8 le dará un buen resultado por tener caracteres no latinos 'simplemente funcionan'.

Sin embargo, si está creando una aplicación más grande o no es el único que trabaja en ella, probablemente querrá algo que sea más fácil de aplicar.

Adaptado de los archivos de la lista de correo de cocoa-dev

@interface NSString (cppstring_additions)
+(NSString*) stringWithwstring:(const std::wstring&)string;
+(NSString*) stringWithstring:(const std::string&)string;
-(std::wstring) getwstring;
-(std::string) getstring;
@end

@implementation NSString (cppstring_additions)

#if TARGET_RT_BIG_ENDIAN
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32BE);
#else
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32LE);
#endif

+(NSString*) stringWithwstring:(const std::wstring&)ws
{
    char* data = (char*)ws.data();
    unsigned size = ws.size() * sizeof(wchar_t);

    NSString* result = [[NSString alloc] initWithBytes:data length:size encoding:kEncoding_wchar_t];
    return result;
}
+(NSString*) stringWithstring:(const std::string&)s
{
    NSString* result = [[NSString alloc] initWithUTF8String:s.c_str()];
    return result;
}

-(std::wstring) getwstring
{
    NSData* asData = [self dataUsingEncoding:kEncoding_wchar_t];
    return std::wstring((wchar_t*)[asData bytes], [asData length] / sizeof(wchar_t));
}
-(std::string) getstring
{
    return [self UTF8String];
}

@end

Con eso en su lugar (y debidamente #importeditado) ahora puede:

NSString* result = [NSString stringWithstring:param];
string convertedBack = [result getstring];

Y lo mismo para std::wstring, que es más que útil.

NSString* mystring = [NSString stringWithUTF8String:stdstring.c_str()];

Apple ahora tiene una nueva forma en la que quieren que hagas esta conversión. En XCode7, utilicé la opción Editar> Convertir> A la sintaxis C moderna de Objective ... para averiguarlo. Utiliza un símbolo @ abreviado.

std::string sCPPString = "Hello World!";
NSString *sAppleString = @(sCPPString.c_str());

También encontré que:

NSString *nsString = [NSString stringWithFormat:@"%s",standardString];

Funciona como un campeón.

Aquí está el fragmento de código / ejemplo:

string str_simple = "HELLO WORLD";

//string to NSString
NSString *stringinObjC = [NSString stringWithCString:str_simple.c_str()
                                encoding:[NSString defaultCStringEncoding]];            
NSLog(stringinObjC);