¿Cómo puedo realizar una búsqueda de cadena inversa en Excel sin usar VBA?

Tengo una hoja de cálculo de Excel que contiene una lista de cadenas. Cada cadena está compuesta por varias palabras, pero el número de palabras en cada cadena es diferente.

Usando las funciones integradas de Excel (sin VBA), ¿hay alguna manera de aislar la última palabra en cada cadena?

Ejemplos:

  ¿Estás clasificado como humano? -> humano?
Negativo, soy una paleta de carne -> paleta
                  Aziz! ¡Ligero! -> ¡Luz!

Este está probado y funciona (según la publicación original de Brad):

=RIGHT(A1,LEN(A1)-FIND("|",SUBSTITUTE(A1," ","|",
     LEN(A1)-LEN(SUBSTITUTE(A1," ","")))))

Si sus cadenas originales pudieran contener una tubería "|" carácter, luego reemplace ambos en lo anterior con algún otro carácter que no aparecerá en su fuente. (Sospecho que el original de Brad estaba roto porque se eliminó un carácter no imprimible en la traducción).

Bonificación: cómo funciona (de derecha a izquierda):

LEN(A1)-LEN(SUBSTITUTE(A1," ",""))- Conteo de espacios en la cadena original
SUBSTITUTE(A1," ","|", ... )- Reemplaza solo el espacio final con un |
FIND("|", ... )- Encuentra la posición absoluta de ese reemplazado |(ese fue el espacio final)
Right(A1,LEN(A1) - ... ))- Devuelve todos los caracteres después de eso|

EDITAR: para tener en cuenta el caso en el que el texto de origen no contiene espacios, agregue lo siguiente al comienzo de la fórmula:

=IF(ISERROR(FIND(" ",A1)),A1, ... )

haciendo toda la fórmula ahora:

=IF(ISERROR(FIND(" ",A1)),A1, RIGHT(A1,LEN(A1) - FIND("|",
    SUBSTITUTE(A1," ","|",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))))

O puede usar la =IF(COUNTIF(A1,"* *")sintaxis de la otra versión.

Cuando la cadena original puede contener un espacio en la última posición, agregue una función de recorte mientras cuenta todos los espacios: Haga que la función sea la siguiente:

=IF(ISERROR(FIND(" ",B2)),B2, RIGHT(B2,LEN(B2) - FIND("|",
    SUBSTITUTE(B2," ","|",LEN(TRIM(B2))-LEN(SUBSTITUTE(B2," ",""))))))

Esta es la técnica que he usado con gran éxito:

=TRIM(RIGHT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Para obtener la primera palabra en una cadena, simplemente cambie de DERECHA a IZQUIERDA

=TRIM(LEFT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Además, reemplace A1 por la celda que contiene el texto.

Una versión más robusta de la respuesta de Jerry:

=TRIM(RIGHT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(TRIM(A1))))

Eso funciona independientemente de la longitud de la cadena, los espacios iniciales o finales, o lo que sea, y sigue siendo bastante corto y simple.

Encontré esto en google, probé en Excel 2003 y funciona para mí:

=IF(COUNTIF(A1,"* *"),RIGHT(A1,LEN(A1)-LOOKUP(LEN(A1),FIND(" ",A1,ROW(INDEX($A:$A,1,1):INDEX($A:$A,LEN(A1),1))))),A1)

[editar] No tengo suficiente representante para comentar, así que este parece el mejor lugar ... La respuesta de BradC tampoco funciona con espacios finales o celdas vacías ...
[2da edición] en realidad, no funciona para palabras sueltas tampoco ...

=RIGHT(TRIM(A1),LEN(TRIM(A1))-FIND(CHAR(7),SUBSTITUTE(" "&TRIM(A1)," ",CHAR(7),
LEN(TRIM(A1))-LEN(SUBSTITUTE(" "&TRIM(A1)," ",""))+1))+1)

Esto es muy robusto: funciona para oraciones sin espacios, espacios iniciales / finales, múltiples espacios, múltiples espacios iniciales / finales ... y utilicé char (7) para el delimitador en lugar de la barra vertical "|" en caso de que sea un elemento de texto deseado.

Esto es muy limpio y compacto, y funciona bien.

{=RIGHT(A1,LEN(A1)-MAX(IF(MID(A1,ROW(1:999),1)=" ",ROW(1:999),0)))}

No es una trampa de error para espacios o una palabra, pero eso es fácil de agregar.

Editar:
maneja espacios finales, una sola palabra y escenarios de celda vacía. No he encontrado una manera de romperlo.

{=RIGHT(TRIM(A1),LEN(TRIM(A1))-MAX(IF(MID(TRIM(A1),ROW($1:$999),1)=" ",ROW($1:$999),0)))}

=RIGHT(A1,LEN(A1)-FIND("`*`",SUBSTITUTE(A1," ","`*`",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))) 

Para agregar a las respuestas de Jerry y Joe, si desea encontrar el texto ANTES de la última palabra, puede usar:

=TRIM(LEFT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))))-LEN(TRIM(A1))))

Con 'My little cat' en A1 daría como resultado 'My little cat' (donde Joe y Jerry's le darían 'cat'

De la misma manera que Jerry y Joe aíslan la última palabra, esto solo pone todo a la izquierda de eso (luego lo recorta)

Imagina que la cuerda se puede revertir. Entonces es realmente fácil. En lugar de trabajar en la cadena:

"My little cat" (1)

usted trabaja con

"tac elttil yM" (2)

Con =LEFT(A1;FIND(" ";A1)-1)en A2 obtienes "My"con (1) y "tac"con (2), que se invierte"cat" , la última palabra en (1).

Hay algunos VBA para revertir una cadena. Prefiero la función pública de VBA ReverseString.

Instale lo anterior como se describe. Luego, con su cadena en A1, por ejemplo, "My little cat"y esta función en A2:

=ReverseString(LEFT(ReverseString(A1);IF(ISERROR(FIND(" ";A1));
  LEN(A1);(FIND(" ";ReverseString(A1))-1))))

lo verás "cat"en A2.

El método anterior supone que las palabras están separadas por espacios en blanco. La IFcláusula es para celdas que contienen palabras simples = sin espacios en blanco en la celda. Nota: TRIMy CLEANla cadena original también son útiles. En principio, invierte toda la cadena desde A1 y simplemente encuentra el primer espacio en blanco en la cadena invertida que está al lado de la última palabra (invertida) (es decir, "tac "). LEFTelige esta palabra y otra inversión de cadena reconstituye el orden original de la palabra ( " cat"). Al -1final de laFIND declaración elimina el espacio en blanco.

La idea es que es fácil de extraer la primera (!) Palabra de una cadena con LEFTe FINDing el primer espacio en blanco. Sin embargo, para la última palabra (!), La RIGHTfunción es la elección incorrecta cuando intenta hacerlo porque desafortunadamente FIND no tiene una bandera para la dirección en la que desea analizar su cadena.

Por lo tanto, toda la cadena simplemente se invierte. LEFTy FINDfunciona normalmente, pero la cadena extraída se invierte. Pero el suyo no es gran cosa una vez que sabe cómo invertir una cadena. La primera ReverseStringdeclaración en la fórmula hace este trabajo.

=LEFT(A1,FIND(IF(
 ISERROR(
  FIND("_",A1)
 ),A1,RIGHT(A1,
  LEN(A1)-FIND("~",
   SUBSTITUTE(A1,"_","~",
    LEN(A1)-LEN(SUBSTITUTE(A1,"_",""))
   )
  )
 )
),A1,1)-2)

Copie en una columna, seleccione esa columna y HOME> Edición> Buscar y seleccionar, reemplazar:

Replace All.

Hay un espacio después del asterisco.

Traduje a PT-BR, ya que también necesitaba esto.

(Tenga en cuenta que he cambiado el espacio a \porque solo necesitaba el nombre de archivo de las cadenas de ruta).

=SE(ÉERRO(PROCURAR("\",A1)),A1,DIREITA(A1,NÚM.CARACT(A1)-PROCURAR("|", SUBSTITUIR(A1,"\","|",NÚM.CARACT(A1)-NÚM.CARACT(SUBSTITUIR(A1,"\",""))))))

Otra forma de lograr esto es la siguiente

=IF(ISERROR(TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14))))),TRIM(D14),TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14)))))

También tuve una tarea como esta y cuando terminé, usando el método anterior, se me ocurrió un nuevo método: ¿Por qué no haces esto?

1. Invierta la cadena ("cadena uno" se convierte en "eno gnirts").
2. Use el viejo y bueno Find (que está codificado de izquierda a derecha).
3. Invierta en cadena legible de nuevo.

¿Como suena esto?