Características ocultas de los archivos por lotes de Windows

¿Cuáles son algunas de las características menos conocidas, pero importantes y útiles de los archivos por lotes de Windows?

Pautas:

• Una característica por respuesta
• Proporcione una breve descripción de la función y un ejemplo , no solo un enlace a la documentación
• Limite las respuestas a la funcionalidad nativa , es decir, no requiere software adicional, como el Kit de recursos de Windows

Aclaración: aquí nos referimos a los scripts procesados ​​por cmd.exe, que es el predeterminado en las variantes de WinNT.

(Ver también: archivos por lotes de Windows: .bat vs .cmd? )

Continuación de línea:

call C:\WINDOWS\system32\ntbackup.exe ^
    backup ^
    /V:yes ^
    /R:no ^
    /RS:no ^
    /HC:off ^
    /M normal ^
    /L:s ^
    @daily.bks ^
    /F daily.bkf

PUSHD path

Te lleva al directorio especificado por ruta .

POPD

Te lleva de vuelta al directorio desde el que "empujaste".

No estoy seguro de cuán útil sería esto en un archivo por lotes , pero es un comando muy conveniente para usar en el símbolo del sistema:

C:\some_directory> start .

Esto abrirá el Explorador de Windows en la carpeta "some_directory".

He encontrado esto un gran ahorro de tiempo.

Siempre me ha resultado difícil leer los comentarios marcados por una palabra clave en cada línea:

REM blah blah blah

Más fácil de leer:

:: blah blah blah

Subcadenas variables:

> set str=0123456789
> echo %str:~0,5%
01234
> echo %str:~-5,5%
56789
> echo %str:~3,-3%
3456

El comando FOR ! Si bien odio escribir archivos por lotes, estoy agradecido por ello.

FOR /F "eol=; tokens=2,3* delims=, " %i in (myfile.txt) do @echo %i %j %k

analizaría cada línea en myfile.txt, ignorando las líneas que comienzan con un punto y coma, pasando la segunda y tercera ficha de cada línea al cuerpo, con fichas delimitadas por comas y / o espacios. Observe que las declaraciones del cuerpo for hacen referencia a% i para obtener el segundo token,% j para obtener el tercer token y% k para obtener todos los tokens restantes después del 3er.

También puede usar esto para iterar sobre directorios, contenidos de directorio, etc.

En lugar de llenar una secuencia de comandos con REM o :: líneas, hago lo siguiente en la parte superior de cada secuencia de comandos:

@echo OFF
goto :START

Description of the script.

Usage:
   myscript -parm1|parm2 > result.txt

:START

Observe cómo puede usar los caracteres de canalización y redirección sin escapar de ellos.

La ruta (con unidad) donde está el script: ~ dp0

set BAT_HOME=%~dp0
echo %BAT_HOME%
cd %BAT_HOME%

La pieza% ~ dp0 ya se mencionó, pero en realidad hay más: los caracteres después de ~ definen la información que se extrae.
Ningún resultado de la letra en el retorno del nombre del archivo de parche
d - devuelve la letra de unidad
p - devuelve la ruta
s - devuelve la ruta corta
x - devuelve la extensión del archivo
Entonces, si ejecuta el script test.bat a continuación desde c: \ Temp \ nombre de directorio largo \ carpeta,

@echo off
echo %0
echo %~d0
echo %~p0
echo %~dp0
echo %~x0
echo %~s0
echo %~sp0

obtienes el siguiente resultado

test
c:
\Temp\long dir name\
c:\Temp\long dir name\
.bat
c:\Temp\LONGDI~1\test.bat
\Temp\LONGDI~1\

Y si se pasa un parámetro a su script como en la
prueba c: \ temp \ mysrc \ test.cpp,
se pueden hacer las mismas manipulaciones con la variable% 1.

¡Pero el resultado de la expansión de% 0 depende de la ubicación!
En el "nivel superior" del lote, se expande al nombre de archivo del lote actual.
En una función (llamada), se expande al nombre de la función.

@echo off
echo %0
call :test
goto :eof

:test
echo %0
echo %~0
echo %~n0

La salida es (el archivo por lotes se inicia con myBatch.bat)

myBatch.bat
:test
:test
myBatch

Al usar CALL, EXIT / B, SETLOCAL & ENDLOCAL puede implementar subrutinas con variables locales.

ejemplo:

@echo off

set x=xxxxx
call :sub 10
echo %x%
exit /b

:sub
setlocal
set /a x=%1 + 1
echo %x%
endlocal
exit /b

Esto imprimirá

11
xxxxx

aunque: sub modifica x.

Truco astuto para esperar N segundos (no es parte de cmd.exe pero no es un software adicional ya que viene con Windows), vea la línea de ping. Necesita N + 1 pings ya que el primer ping se ejecuta sin demora.

    echo %time%
    call :waitfor 5
    echo %time%
    goto :eof
:waitfor
    setlocal
    set /a "t = %1 + 1"
    >nul ping 127.0.0.1 -n %t%
    endlocal
    goto :eof

Escapar de la "fontanería":

echo ^| ^< ^> ^& ^\ ^^

Ser capaz de ejecutar comandos y procesar la salida (como los backticks de '$ ()' en bash).

for /f %i in ('dir /on /b *.jpg') do echo --^> %i

Si hay espacios en los nombres de archivo, use esto:

for /f "tokens=*" %i in ('dir /on /b *.jpg') do echo --^> %i

Crear un archivo vacío:

> copy nul filename.ext

Para ocultar toda la salida de un comando, redirija a> nul 2> & 1.

Por ejemplo, algunos programas de línea de comandos muestran resultados incluso si redirige a> nul. Pero, si redirige la salida como la línea de abajo, se suprimirá toda la salida.

PSKILL NOTEPAD >nul 2>&1

EDITAR: Consulte Ignorar la salida de un comando para obtener una explicación de cómo funciona esto.

PAUSE

Detiene la ejecución y muestra el siguiente mensaje:

Pulse cualquier tecla para continuar . . .

Es útil si desea ejecutar un lote haciendo doble clic en el Explorador de Windows y desea ver realmente el resultado en lugar de solo un destello de la ventana de comandos.

El equivalente de la fiesta (y otras conchas)

echo -n Hello # or
echo Hello\\c

que genera " Hello" sin una nueva línea final. Un hack de cmd para hacer esto:

<nul set /p any-variable-name=Hello

set /pes una forma de solicitar al usuario que ingrese. Emite la cadena dada y luego espera (en la misma línea, es decir, sin CRLF), para que el usuario escriba una respuesta.

<nulsimplemente canaliza una respuesta vacía al set /pcomando, por lo que el resultado neto es la cadena de solicitud emitida. (La variable utilizada permanece sin cambios debido a la respuesta vacía).

Los problemas son: no es posible generar un signo de igualdad inicial, y en Vista se eliminan los espacios en blanco iniciales, pero no en XP.

Busque y reemplace cuando establezca variables de entorno:

> @set fname=%date:/=%

... elimina el "/" de una fecha para usar en nombres de archivo con marca de tiempo.

y subcadenas también ...

> @set dayofweek=%fname:~0,3%

Aritmética de enteros:

> SET /A result=10/3 + 1
4

Separadores de comando:

cls & dir
copy a b && echo Success
copy a b || echo Failure

En la segunda línea, el comando después de && solo se ejecuta si el primer comando es exitoso.

En la tercera línea, el comando después de || solo se ejecuta si falla el primer comando.

Salida de una línea en blanco:

echo.

Puede encadenar sentencias if para obtener un efecto como un booleano de cortocircuito `y '.

if foo if bar baz

Para convertir rápidamente un archivo de texto Unicode (16 bits / char) en un archivo ASCII DOS (8 bits / char).

C:\> type unicodeencoded.txt > dosencoded.txt

Como bonificación, si es posible, los personajes están correctamente mapeados.

si estructura de bloque:

if "%VS90COMNTOOLS%"=="" (
  echo: Visual Studio 2008 is not installed
  exit /b
)

Expansión retardada de variables (con subcadenas incluidas).

    @echo off
    setlocal enableextensions enabledelayedexpansion
    set full=/u01/users/pax
:loop1
    if not "!full:~-1!" == "/" (
        set full2=!full:~-1!!full2!
        set full=!full:~,-1!
        goto :loop1
    )
    echo !full!
    endlocal

No proporciona mucha funcionalidad, pero puede usar el comando de título para un par de usos, como proporcionar estado en un script largo en la barra de tareas, o simplemente para mejorar los comentarios de los usuarios.

@title Searching for ...
:: processing search
@title preparing search results
:: data processing

¿No tiene un editor a mano y necesita crear un archivo por lotes?

copy con test.bat

Simplemente escriba los comandos, presione Entrar para una nueva línea. Presione Ctrl-Z e Intro para cerrar el archivo.

ejemplo de resta de cadenas en datey timepara obtener el archivo llamado "AAAA-MM-DD HH: MM: SS.txt"

echo test > "%date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%_%time:~3,2%_%time:~6,2%.txt"

Utilizo colorpara indicar si mi script termina con éxito, falla o necesita alguna entrada cambiando el color del texto y el fondo. Realmente ayuda cuando tienes alguna máquina al alcance de tu vista pero bastante lejos

color XY

donde X e Y es el valor hexadecimal de 0a F, donde X - fondo, Y - texto, cuando X = Y el color no cambiará.

color Z

cambia el color del texto a 'Z' y establece el fondo negro, 'color 0' no funcionará

para nombres de colores llama

color ?

Control total sobre la salida con espaciado y caracteres de escape .:

echo.    ^<resourceDir^>/%basedir%/resources^</resourceDir^>

TheSoftwareJedi ya mencionó el comando for, pero lo mencionaré nuevamente ya que es muy poderoso.

A continuación se muestra la fecha actual en el formato AAAAMMDD, lo uso al generar directorios para copias de seguridad.

for /f "tokens=2-4 delims=/- " %a in ('DATE/T') do echo %c%b%a