Operadores lógicos ("y", "o") en lote DOS

¿Cómo implementaría operadores lógicos en archivos DOS Batch?

Puedes hacerlo andcon condiciones anidadas:

if %age% geq 2 (
    if %age% leq 12 (
        set class=child
    )
)

o:

if %age% geq 2 if %age% leq 12 set class=child

Puedes hacerlo orcon una variable separada:

set res=F
if %hour% leq 6 set res=T
if %hour% geq 22 set res=T
if "%res%"=="T" (
    set state=asleep
)

La IFdeclaración no admite operadores lógicos ( ANDy OR), las IFdeclaraciones en cascada hacen una conjunción implícita.

IF Exist File1.Dat IF Exist File2.Dat GOTO FILE12_EXIST_LABEL

Si File1.Dat y File1.Dat existe, salta la etiqueta FILE12_EXIST_LABEL.

Ver también: IF /?

Las leyes de De Morgan nos permiten convertir las disyunciones ("O") en equivalentes lógicos utilizando solo conjunciones ("Y") y negaciones ("NO"). Esto significa que podemos encadenar disyunciones ("OR") en una sola línea.

Esto significa que si el nombre es "Yakko" o "Wakko" o "Dot", entonces repite "Hermano o hermana Warner".

set warner=true
if not "%name%"=="Yakko" if not "%name%"=="Wakko" if not "%name%"=="Dot" set warner=false
if "%warner%"=="true" echo Warner brother or sister

Esta es otra versión del ejemplo "OR" de paxdiablo, pero las condiciones están encadenadas a una sola línea. (Tenga en cuenta que lo opuesto de leqes gtry lo opuesto de geqes lss).

set res=true
if %hour% gtr 6 if %hour% lss 22 set res=false
if "%res%"=="true" set state=asleep

Los siguientes ejemplos muestran cómo hacer una declaración AND (utilizada para establecer variables o incluir parámetros para un comando).

Para iniciar el Bloc de notas y cerrar la ventana CMD:

start notepad.exe & exit

Para establecer las variables x, y y z en valores si la variable 'a' es igual a bla.

IF "%a%"=="blah" (set x=1) & (set y=2) & (set z=3)

¡Espero que ayude!

O es un poco complicado, pero no demasiado. Aquí hay un ejemplo

set var1=%~1
set var2=%~2
::
set or_=
if "%var1%"=="Stack" set or_=true
if "%var2%"=="Overflow" set or_=true
if defined or_ echo Stack OR Overflow

Athul Prakash (16 años en ese momento) dio una idea lógica de cómo implementar una prueba OR al negar las condiciones en las declaraciones IF y luego usar la cláusula ELSE como la ubicación para colocar el código que requiere ejecución. Pensé para mí mismo que, sin embargo, normalmente se necesitan dos cláusulas más, ya que sugiere usar dos declaraciones IF, por lo que el código ejecutado debe escribirse dos veces . Sin embargo, si se usa un GOTO para omitir el código requerido, en lugar de escribir cláusulas ELSE, el código para la ejecución solo debe escribirse una vez .

Aquí hay un ejemplo comprobable de cómo implementaría la lógica negativa de Athul Prakash para crear un OR .

En mi ejemplo, a alguien se le permite conducir un tanque si tiene una licencia de tanque O está haciendo su servicio militar . Ingrese verdadero o falso en las dos indicaciones y podrá ver si la lógica le permite conducir un tanque.

@ECHO OFF
@SET /p tanklicence=tanklicence:
@SET /p militaryservice=militaryservice:

IF /I NOT %tanklicence%==true IF /I NOT %militaryservice%==true GOTO done

ECHO I am driving a tank with tanklicence set to %tanklicence% and militaryservice set to %militaryservice%

:done

PAUSE

Si está interesado en escribir un if+ AND/ ORen una declaración, entonces no hay nada de eso. Pero, aún puede agrupar ifcon &&/ ||y (/ )declaraciones para lograr lo que desea en una línea sin variables adicionales y sin if-elseduplicación de bloque ( echocomando único para TRUEy FALSEsecciones de código):

@echo off

setlocal

set "A=1" & set "B=2" & call :IF_AND
set "A=1" & set "B=3" & call :IF_AND
set "A=2" & set "B=2" & call :IF_AND
set "A=2" & set "B=3" & call :IF_AND

echo.

set "A=1" & set "B=2" & call :IF_OR
set "A=1" & set "B=3" & call :IF_OR
set "A=2" & set "B=2" & call :IF_OR
set "A=2" & set "B=3" & call :IF_OR

exit /b 0

:IF_OR
( ( if %A% EQU 1 ( type nul>nul ) else type 2>nul ) || ( if %B% EQU 2 ( type nul>nul ) else type 2>nul ) || ( echo.FALSE-& type 2>nul ) ) && echo TRUE+

exit /b 0

:IF_AND
( ( if %A% EQU 1 ( type nul>nul ) else type 2>nul ) && ( if %B% EQU 2 ( type nul>nul ) else type 2>nul ) && echo.TRUE+ ) || echo.FALSE-


exit /b 0

Salida :

TRUE+
FALSE-
FALSE-
FALSE-

TRUE+
TRUE+
TRUE+
FALSE-

El truco está en el typecomando que suelta / establece errorlevely, por lo tanto, maneja el camino hacia el siguiente comando.

Pruebe el operando de negación - 'no'!

Bueno, si puede realizar la operación 'AND' en una instrucción if utilizando 'if' anidados (consulte las respuestas anteriores), entonces puede hacer lo mismo con 'if not' para realizar una operación 'u'.

Si todavía no tienes la idea, sigue leyendo. De lo contrario, no pierdas tu tiempo y vuelve a la programación.

Así como los 'si' anidados se satisfacen solo cuando todas las condiciones son verdaderas, los 'si no' anidados se satisfacen solo cuando todas las condiciones son falsas. Esto es similar a lo que quieres hacer con un operando 'u', ¿no?

Incluso cuando cualquiera de las condiciones en el 'si no' anidado es verdadera, toda la declaración sigue sin cumplirse. Por lo tanto, puede usar 'if' negados en sucesión recordando que el cuerpo de la declaración de condición debería ser lo que desea hacer si todas sus condiciones anidadas son falsas. El cuerpo que realmente querías dar debería venir bajo la declaración else.

Y si aún no entendiste el truco, lo siento, tengo 16 años y eso es lo mejor que puedo hacer para explicarte.

Es tan fácil como lo siguiente:

Y> si + si

if "%VAR1%"=="VALUE" if "%VAR2%"=="VALUE" *do something*

O> si // si

set BOTH=0
if "%VAR1%"=="VALUE" if "%VAR2%"=="VALUE" set BOTH=1
if "%BOTH%"=="0" if "%VAR1%"=="VALUE" *do something*
if "%BOTH%"=="0" if "%VAR2%"=="VALUE" *do something*

Sé que hay otras respuestas, pero creo que la mina es más simple, por lo que es más fácil de entender. ¡Espero que esto te ayude! ;)

Una alternativa es buscar un shell de Unix que le brinde operadores lógicos y mucho más. Puede obtener una implementación win32 nativa de un shell Bourne aquí si no desea seguir la ruta cygwin. Una fiesta nativa se puede encontrar aquí . Estoy bastante seguro de que podría buscar fácilmente otras buenas alternativas como zsh o tcsh.

K

Solo la parte OR es complicada, pero con una expresión booleana general que contiene NOT OR AND, la única buena solución es esta:

REM if A == B OR C == C then yes

(call :strequ A B || call :strequ C C) && echo yes
exit /b

:strequ
if "%1" == "%2" exit /b 0
exit /b 1

Ligera modificación a la respuesta de Andry, reduciendo los comandos de tipo duplicado:

set "A=1" & set "B=2" & call :IF_AND
set "A=1" & set "B=3" & call :IF_AND
set "A=2" & set "B=2" & call :IF_AND
set "A=2" & set "B=3" & call :IF_AND

echo.

set "A=1" & set "B=2" & call :IF_OR
set "A=1" & set "B=3" & call :IF_OR
set "A=2" & set "B=2" & call :IF_OR
set "A=2" & set "B=3" & call :IF_OR

goto :eof

:IF_OR

(if /i not %A% EQU 1 (
   if /i not %B% EQU 2 (
      echo FALSE-
      type 2>nul
   )
)) && echo TRUE+

goto :eof

:IF_AND


(if /i %A% EQU 1 (
   if /i %B% EQU 2 (
      echo TRUE+
      type 2>nul
   )
)) && echo FALSE-

goto :eof