He agregado notepad++.exea mi ruta en las variables de entorno.

Ahora en el símbolo del sistema, notepad++.exe filename.txtabre el filename.txt. Pero quiero hacer solo np filename.txtpara abrir el archivo.

Traté de usar DOSKEY np=notepad++. Pero solo está poniendo en primer plano un bloc de notas ++ ya abierto sin abrir el archivo. ¿Cómo puedo hacer que abra el archivo?

Gracias.

Para agregar a la respuesta de Josh,

puede hacer que los alias sean persistentes con los siguientes pasos,

1. Cree un archivo .bat o .cmd con sus DOSKEYcomandos.
2. Ejecute regedit y vaya a HKEY_CURRENT_USER\Software\Microsoft\Command Processor

3. Agregue la entrada de valor de cadena con el nombre AutoRuny la ruta completa de su archivo .bat / .cmd.

   Por ejemplo, %USERPROFILE%\alias.cmdreemplazar el segmento inicial de la ruta %USERPROFILE%es útil para sincronizar entre múltiples máquinas.

De esta manera, cada vez que se ejecuta cmd, se cargan los alias.

Para Windows 10 , agregue la entrada a en su HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command Processorlugar.

Para completar, aquí hay una plantilla para ilustrar el tipo de alias que uno puede encontrar útil.

@echo off

:: Temporary system path at cmd startup

set PATH=%PATH%;"C:\Program Files\Sublime Text 2\"

:: Add to path by command

DOSKEY add_python26=set PATH=%PATH%;"C:\Python26\"
DOSKEY add_python33=set PATH=%PATH%;"C:\Python33\"

:: Commands

DOSKEY ls=dir /B
DOSKEY sublime=sublime_text $*  
    ::sublime_text.exe is name of the executable. By adding a temporary entry to system path, we don't have to write the whole directory anymore.
DOSKEY gsp="C:\Program Files (x86)\Sketchpad5\GSP505en.exe"
DOSKEY alias=notepad %USERPROFILE%\Dropbox\alias.cmd

:: Common directories

DOSKEY dropbox=cd "%USERPROFILE%\Dropbox\$*"
DOSKEY research=cd %USERPROFILE%\Dropbox\Research\

• Tenga en cuenta que la $*sintaxis funciona después de una cadena de directorio, así como un ejecutable que toma argumentos. Entonces, en el ejemplo anterior, el comando definido por el usuario dropbox researchapunta al mismo directorio que research.
• Como señaló Rivenfall, es una buena idea incluir un comando que permita la edición conveniente del alias.cmdarchivo. Ver aliasarriba Si está en una sesión de cmd, ingrese cmdpara reiniciar cmd y vuelva a cargar el alias.cmdarchivo.

Cuando busqué en Internet una respuesta a la pregunta, de alguna manera las discusiones se centraron en la persistencia solamente o en el uso de DOSKEY solamente. ¡Espero que alguien se beneficie de estos dos aspectos al estar juntos aquí!

Aquí hay un .regarchivo para ayudarlo a instalar el alias.cmd. Ahora se configura como un ejemplo para una carpeta de Dropbox como se sugirió anteriormente.

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="%USERPROFILE%\\alias.cmd"

Para aplicaciones de un solo usuario, lo anterior servirá. Sin embargo, hay situaciones en las que es necesario verificar si alias.cmdexiste primero en la clave de registro. Ver ejemplo a continuación.

En un C:\Users\Public\init.cmdarchivo que aloja configuraciones potencialmente entre usuarios:

@ECHO OFF
REM Add other configurations as needed
IF EXIST "%USERPROFILE%\alias.cmd" ( CALL "%USERPROFILE%\alias.cmd" )

La clave de registro debe actualizarse de manera correspondiente C:\Users\Public\init.cmdo, utilizando el .regarchivo:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="C:\\Users\\Public\\init.cmd"

Debe pasar los parámetros, intente esto:

doskey np=notepad++.exe $*

Editar (en respuesta al comentario de Romonov) P: ¿Hay alguna forma de recordar el símbolo del sistema para que no tenga que ejecutar esto cada vez que abro un nuevo símbolo del sistema?

doskey es un comando textual interpretado por el procesador de comandos (por ejemplo, cmd.exe), no puede saber cómo modificar el estado en algún otro proceso (especialmente uno que aún no se ha iniciado).

Las personas que usan doskeypara configurar sus entornos de shell de comandos iniciales generalmente usan la /Kopción (a menudo a través de un acceso directo) para ejecutar un archivo por lotes que realiza toda la configuración común (título de la ventana, colores, etc.).

cmd.exe /K env.cmd

env.cmd:

title "Foo Bar"
doskey np=notepad++.exe $*
...

Si solo quiere algunos comandos simples, puede seguir estos pasos:

1. Cree una carpeta llamada C: \ Aliases
2. Agregue C: \ Alias a su ruta (para que todos los archivos se encuentren cada vez)
3. Cree un archivo .bat en C: \ Alias ​​para cada uno de los alias que desee

Tal vez exagere, pero a diferencia de la respuesta (por lo demás excelente) de @Argyll, esto resuelve el problema de esta carga cada vez.

Por ejemplo, tengo un archivo llamado dig2.bat con lo siguiente:

@echo off
echo.
dig +noall +answer %1

Su archivo np solo tendría lo siguiente:

@echo off
echo.
notepad++.exe %1

Luego, simplemente agregue la carpeta C: \ Aliases a su variable de entorno PATH. Si ya tiene CMD o PowerShell abierto, deberá reiniciarlo.

FWIW, tengo alrededor de 20 alias (archivos .bat separados) en mi directorio C: \ Aliases, solo creo nuevos según sea necesario. Quizás no sea el más lindo, pero funciona bien.

ACTUALIZACIÓN : según una excelente sugerencia del usuario @Mav, es aún mejor usar % * en lugar de % 1 , por lo que puede pasar varios archivos al comando, por ejemplo:

@echo off
echo.
notepad++.exe %*

De esa manera, podrías hacer esto:

np c:\temp\abc.txt c:\temp\def.txt c:\temp\ghi.txt

y abrirá los 3 archivos.

Alternativamente, puede usar lo cmderque le permite agregar alias al igual que Linux:

alias subl="C:\Program Files\Sublime Text 3\subl.exe" $*

Dado que agregó notepad ++. Exe a su variable PATH, es muy simple. Cree un archivo en su carpeta System32 llamado np.batcon el siguiente código:

@echo off
call notepad++.exe %*

El %*pasa todos los argumentos que le da el npcomando al notepad++.execomando.

EDITAR: necesitará acceso de administrador para guardar archivos en la carpeta System32, lo cual fue un poco raro para mí. Acabo de crear el archivo en otro lugar y lo moví a System32 manualmente.

Además, puede crear un alias.cmd en su ruta (por ejemplo, C: \ Windows) con el comando

@echo %2 %3 %4 %5 %6 > %windir%\%1.cmd

Una vez que hagas eso, puedes hacer algo como esto:

alias nameOfYourAlias commands to run 

Y después de eso puedes escribir la línea de comando

nameOfYourAlias 

esto ejecutará

commands to run 

PERO la mejor manera para mí es simplemente agregar la ruta de un programa.

setx PATH "%PATH%;%ProgramFiles%\Sublime Text 3" /M 

Y ahora corro sublime como

subl index.html

Alias ​​de consola en Windows 10

Para definir un alias de consola, use Doskey.exepara crear una macro, o use la AddConsoleAliasfunción.

doskey

doskey test=cd \a_very_long_path\test

Para pasar también parámetros agregue $*al final:doskey short=longname $*

AddConsoleAlias

AddConsoleAlias( TEXT("test"), 
                 TEXT("cd \\<a_very_long_path>\\test"), 
                 TEXT("cmd.exe"));

Más información aquí, la consola de Alias , Doskey , Parámetros

Desea crear un alias simplemente escribiendo:

c:\>alias kgs kubectl get svc

Created alias for kgs=kubectl get svc

Y use el alias de la siguiente manera:

c:\>kgs alfresco-svc

NAME           TYPE        CLUSTER-IP     EXTERNAL-IP   PORT(S)   AGE
alfresco-svc   ClusterIP   10.7.249.219   <none>        80/TCP    8d

Simplemente agregue el siguiente alias.batarchivo a su ruta. Simplemente crea archivos por lotes adicionales en el mismo directorio que él mismo.

  @echo off
  echo.
  for /f "tokens=1,* delims= " %%a in ("%*") do set ALL_BUT_FIRST=%%b
  echo @echo off > C:\Development\alias-script\%1.bat
  echo echo. >> C:\Development\alias-script\%1.bat
  echo %ALL_BUT_FIRST% %%* >> C:\Development\alias-script\%1.bat
  echo Created alias for %1=%ALL_BUT_FIRST%

Un ejemplo del archivo por lotes que este llamado creado kgs.bates:

@echo off 
echo. 
kubectl get svc %* 

En realidad, iré mejor y te dejaré entrar en una pequeña técnica que he usado desde que solía programar en un Amiga. En cualquier sistema nuevo que use, ya sea personal o profesional, el primer paso es crear dos carpetas: C:\BINy C:\BATCH. Luego, modifique su declaración de ruta para colocar ambas al principio en el orden C:\BATCH;C:\BIN;[rest of path].

Una vez hecho esto, si tiene pequeñas utilidades fuera de la ruta a las que necesita acceso, simplemente cópielas en la C:\BINcarpeta y estarán en su camino. Para anular temporalmente estas asignaciones, puede agregar un archivo por lotes con el mismo nombre que el ejecutable alC:\BATCH carpeta y la ruta lo encontrará antes del archivo en C: \ BIN. Debería cubrir todo lo que necesite hacer.

Por supuesto, en estos días la forma canónica correcta de hacer esto sería crear una unión simbólica al archivo, pero se aplica el mismo principio. También hay una pequeña bonificación adicional. Si desea poner algo en el sistema que entre en conflicto con algo que ya está en el camino, ponerlo en la carpeta C:\BINo C:\Batchsimplemente se adelantará al original, lo que le permitirá anular cosas de forma temporal o permanente, o cambiar el nombre de las cosas a los nombres más cómodo con - sin alterar realmente el original.

Ampliando en respuesta roryhewitt .

Una ventaja de usar archivos .cmd sobre DOSKEY es que estos "alias" están disponibles en otros shells como PowerShell o WSL (subsistema de Windows para Linux).

El único inconveniente con el uso de estos comandos en bash es que puede requerir un poco más de configuración, ya que es posible que deba realizar alguna manipulación de ruta antes de llamar a su "alias".

por ejemplo, tengo vs.cmd, que es mi "alias" para editar un archivo en Visual Studio

@echo off
if [%1]==[] goto nofiles
start "" "c:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" /edit %1
goto end
:nofiles
start "" "C:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" "[PATH TO MY NORMAL SLN]"
:end

Lo que enciende VS (en este caso VS2012, pero se ajusta al gusto) usando mi proyecto "normal" sin archivo dado, pero cuando se le da un archivo, intentará adjuntarlo a un VS en ejecución abriendo ese archivo "dentro de ese proyecto" en lugar de comenzar un nueva instancia de VS.

Para usar esto desde bash, agrego un nivel adicional de indirección ya que "vs Myfile" no siempre funcionaría

alias vs='/usr/bin/run_visual_studio.sh'

Que ajusta las rutas antes de llamar a vs.cmd

#!/bin/bash
cmd.exe /C 'c:\Windows\System32\vs.cmd' "`wslpath.sh -w -r $1`"

Entonces de esta manera puedo hacer

vs SomeFile.txt

Ya sea en un símbolo del sistema, Power Shell o bash y se abre en mi Visual Studio en ejecución para editar (lo que simplemente evita que mi pobre cerebro tenga que lidiar con comandos VI o algo así cuando he estado editando en VS durante horas).

Esta solución no es adecuada, pero tiene un propósito en algunas ocasiones.

Primero cree una carpeta y agréguela a la ruta del sistema. Vaya al ejecutable de cualquier programa para el que desee crear un alias. Haga clic derecho y enviar al escritorio (Crear acceso directo). Cambie el nombre del acceso directo a cualquier nombre de alias que sea cómodo. Ahora, toma el atajo y colócalo en tu carpeta.

Desde el indicador de ejecución, puede escribir el nombre del acceso directo directamente y puede tener el programa abierto para usted. Pero desde el símbolo del sistema, debe agregar .lnk y presionar enter, el programa se abrirá.

Naturalmente, no descansaría hasta tener la solución más conveniente de todas. Combinando las muchas respuestas y temas en la vasta Internet, esto es lo que puede tener.

• Se carga automáticamente con cada instancia de cmd
• No requiere palabra clave DOSKEYpara alias

Tenga en cuenta que esto se basa en gran medida en la respuesta y los comentarios de Argyll , definitivamente léalo para comprender los conceptos.

¿Cómo funciona?

1) cree un archivo macro con alias (o un archivo bat / cmd para ejecutar también otras cosas)
2) regístrelo en el Registro para ejecutarlo en cada instancia de cmd
  ; también puede ejecutarlo mediante un acceso directo solo si lo desea

Eso es todo

;==============================================================================
;= This file is registered via registry to auto load with each instance of cmd.
;================================ general info ================================
;= https://stackoverflow.com/a/59978163/985454  -  how to set it up?
;= https://gist.github.com/postcog/5c8c13f7f66330b493b8  -  example doskey macrofile
;========================= loading with cmd shortcut ==========================
;= create a cmd link with the following target :
;= %comspec% /k "(doskey /macrofile=%userprofile%\cmd\aliases.mac)"

alias=subl %USERPROFILE%\cmd\aliases.mac
hosts=runas /noprofile /savecred /user:QWERTY-XPS9370\administrator "subl C:\Windows\System32\drivers\etc\hosts" > NUL

ls=ls --color=auto $*
ll=ls -l --color=auto $*
la=ls -la --color=auto $*
grep=grep --color

~=cd %USERPROFILE%
cdr=cd c:\repos
cdd=cd c:\repos\dixons
cds=cd c:\repos\stekkie
cdu=cd c:\repos\uplus
cduo=cd c:\repos\uplus\oxbridge-fe
cdus=cd c:\repos\uplus\stratus

;============================= :end ============================
;= rem ******************************************************************
;= rem * EOF - Don't remove the following line.  It clears out the ';'
;= rem * macro. We're using it because there is no support for comments
;= rem * in a DOSKEY macro file.
;= rem ******************************************************************
;=

Ahora tiene dos opciones:
a) registrar solo el macrofile
b) usar un cmd/batarchivo normal para ejecutar también comandos arbitrarios
Cambie el nombre del que desea Autorun.

  Autorun    REG_SZ    doskey /macrofile=%userprofile%\cmd\aliases.mac
  Autorun_    REG_SZ    %USERPROFILE%\cmd\env.cmd

Windows Registry Editor Version 5.00
[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"Autorun"="doskey /macrofile=%userprofile%\\cmd\\aliases.mac"
"Autorun_"="%USERPROFILE%\\cmd\\env.cmd"

:: This file is registered via registry to auto load with each instance of cmd.
:: https://stackoverflow.com/a/59978163/985454

@echo off
doskey /macrofile=%userprofile%\cmd\aliases.mac

:: put other commands here

Como ya lo tienes notepad++.exeen tu camino. Cree un acceso directo en esa carpeta llamada npy apúntelo notepad++.exe.

Primero, puede crear un archivo llamado np.cmd y ponerlo en la carpeta que se encuentra en la lista de búsqueda PATH. Luego, edite el archivo np.cmd como se muestra a continuación:

@echo off
notepad++.exe

Si desea habilitar los alias por directorio / por proyecto , intente lo siguiente:

1. Primero, cree un archivo por lotes que buscará un archivo nombrado aliasesen el directorio actual e inicializará los alias, llamémoslomake-aliases.cmd

   @echo off
   if not exist aliases goto:eof
   echo [Loading aliases...]
   for /f "tokens=1* delims=^=" %%i in (aliases) do (
      echo   %%i ^<^=^> %%j
      doskey %%i=%%j
   )
   doskey aliases=doskey /macros
   echo   --------------------
   echo   aliases ^=^> list  all
   echo   alt+F10 ^=^> clear all
   echo [Done]
   

2. Luego, cree aliasesdonde sea que los necesite con el siguiente formato:

   alias1 = command1
   alias2 = command2
   ...
   

   por ejemplo:

   b = nmake
   c = nmake clean
   r = nmake rebuild
   

3. Luego, agregue la ubicación de make-aliases.cmdsu %PATH%variable para que sea de todo el sistema o simplemente manténgala en un lugar conocido.

4. Haz que comience automáticamente con cmd.

   • Definitivamente, recomendaría no usarlo HKEY_CURRENT_USER\Software\Microsoft\Command Processor\AutoRunpara esto, porque algunas herramientas de desarrollo activarían el script de ejecución automática varias veces por sesión.

   • Si utiliza ConEmu usted podría ir por otro camino y comenzar la secuencia de comandos de inicio de la tarea ( Settings> Startup> Tasks), por ejemplo, he creado una entrada llamada {MSVC}:

     cmd.exe /k "vcvars64 && make-aliases",

     y luego lo registré en el menú contextual del Explorador a través de Settings> Integration>con Command: {MSVC} -cur_console:n, de modo que ahora puedo hacer clic con el botón derecho en una carpeta e iniciar un indicador de desarrollador VS dentro con mi aliasescargado automáticamente, si están en esa carpeta.

     Sin ConEmu, es posible que solo desee crear un acceso directo cmd.execon el comando correspondiente o simplemente ejecutarlo make-aliasesmanualmente cada vez.

Si olvida sus alias, use la aliasesmacro y, si algo sale mal, simplemente restablezca la sesión actual presionando Alt+ F10, que es un comando incorporado cmd.

Usar doskey es la forma correcta de hacer esto, pero se restablece cuando se cierra la ventana del símbolo del sistema. Necesita agregar esa línea a algo como .bashrc equivalente. Entonces hice lo siguiente:

1. Agregue "C: \ Archivos de programa (x86) \ Notepad ++" a la variable de ruta del sistema
2. Haga una copia de notepad ++. Exe (en la misma carpeta, por supuesto) y cámbiele el nombre a np.exe

Funciona bien!