¿Qué es un gancho previo al cambio de revprop en SVN y cómo lo creo?

Quería editar un comentario de registro en el navegador del repositorio y recibí un mensaje de error que indica que no existe un enlace previo al cambio de revprop para el repositorio. Además de tener un nombre aterrador, ¿qué es un gancho previo al cambio de revprop y cómo lo creo?

Básicamente es un script que se inicia antes de que la propiedad no versionada se modifique en el repositorio, para que pueda administrar con mayor precisión lo que sucede en su repositorio.

Hay plantillas en la distribución SVN para diferentes enlaces, ubicados en el subdirectorio / hooks (* .tmpl que debe editar y renombrar dependiendo de su sistema operativo, para activar).

Para Windows, aquí hay un enlace a un archivo por lotes de ejemplo que solo permite cambios en el mensaje de registro (no otras propiedades):

http://ayria.livejournal.com/33438.html

Básicamente, copie el siguiente código en un archivo de texto y asígnele un nombre pre-revprop-change.baty guárdelo en el \hookssubdirectorio para su repositorio.

@ECHO OFF
:: Set all parameters. Even though most are not used, in case you want to add
:: changes that allow, for example, editing of the author or addition of log messages.
set repository=%1
set revision=%2
set userName=%3
set propertyName=%4
set action=%5

:: Only allow the log message to be changed, but not author, etc.
if /I not "%propertyName%" == "svn:log" goto ERROR_PROPNAME

:: Only allow modification of a log message, not addition or deletion.
if /I not "%action%" == "M" goto ERROR_ACTION

:: Make sure that the new svn:log message is not empty.
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
set bIsEmpty=false
)
if "%bIsEmpty%" == "true" goto ERROR_EMPTY

goto :eof

:ERROR_EMPTY
echo Empty svn:log messages are not allowed. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Only changes to svn:log messages are allowed. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Only modifications to svn:log revision properties are allowed. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1

Para que Linux permita la edición de un comentario de registro,

• ubique el archivo pre-revprop-change.tmplen el hooksdirectorio de su repositorio
• copie el archivo en el mismo directorio, renombrándolo a pre-revprop-change
• dar permiso de ejecución al archivo (para el usuario del servidor, por ejemplo www-data)

Editado: (gracias a lindes)

• después de eso, es posible que deba editar el script para devolver un valor de salida 0para el tipo de ediciones que desea permitir.

Aquí está el enlace a la pregunta de desbordamiento de la pila con muchos enlaces comunes Tipos comunes de enlaces de subversión , incluida la fuente original del enlace pre-revprop-changepara Windows con publicación cruzada aquí.

Debe consultar allí ya que pueden mejorar con el tiempo.

Gracias #patmortech

Y agregué su código que "solo el mismo usuario puede cambiar su código".

:: Only allow editing of the same user.
for /f "tokens=*" %%a in ( 
'"%VISUALSVN_SERVER%\bin\svnlook.exe" author -r %revision% %repository%') do ( 
set orgAuthor=%%a
)
if /I not "%userName%" == "%orgAuthor%" goto ERROR_SAME_USER

El nombre del script de enlace no da tanto miedo si logra descifrarlo: es el enlace de cambio de propiedad previo a la revisión . En resumen, el propósito depre-revprop-change secuencia comandos enlace es controlar los cambios de las propiedades no versionadas (revisión) y enviar notificaciones (por ejemplo, enviar un correo electrónico cuando se cambia la propiedad de revisión).

Hay 2 tipos de propiedades en Subversion:

• propiedades versionadas (p. ej. svn:needs-lockysvn:mime-type ) que se pueden configurar en archivos y directorios,
• propiedades no revisadas (revisión) (por ejemplo, svn:logy svn:date) que se establecen en las revisiones del repositorio .

Las propiedades versionadas tienen historial y pueden ser manipuladas por usuarios comunes que tienen acceso de lectura / escritura a un repositorio. Por otro lado, las propiedades no versionadas no tienen ningún historial y sirven principalmente para fines de mantenimiento. Por ejemplo, si confirma una revisión, inmediatamente obtienesvn:date con la hora UTC de su confirmación, svn:authorcon su nombre de usuario y svn:logcon su mensaje de registro de confirmación (si especificó alguno).

Como ya especifiqué, el propósito del pre-revprop-changescript de enlace es controlar los cambios de las propiedades de revisión. No desea que todos los que tienen acceso a un repositorio puedan modificar todas las propiedades de revisión, por lo que está prohibido cambiar las propiedades de revisión de forma predeterminada. Para permitir que los usuarios cambien propiedades, debe crearpre-revprop-change enlace.

El gancho más simple puede contener solo una línea: exit 0 . Permitirá que cualquier usuario autenticado cambie cualquier propiedad de revisión y no debe usarse en un entorno real. En Windows, puede usar un script por lotes o un script basado en PowerShell para implementar algo de lógica dentro del pre-revprop-changeenlace.

Este script de PowerShell permite cambiar svn:logsolo propiedades y niega los mensajes de registro vacíos.

# Store hook arguments into variables with mnemonic names
$repos    = $args[0]
$rev      = $args[1]
$user     = $args[2]
$propname = $args[3]
$action   = $args[4]

# Only allow changes to svn:log. The author, date and other revision
# properties cannot be changed
if ($propname -ne "svn:log")
{
  [Console]::Error.WriteLine("Only changes to 'svn:log' revision properties are allowed.")
  exit 1
}

# Only allow modifications to svn:log (no addition/overwrite or deletion)
if ($action -ne "M")
{
  [Console]::Error.WriteLine("Only modifications to 'svn:log' revision properties are allowed.")
  exit 2
}

# Read from the standard input while the first non-white-space characters
$datalines = ($input | where {$_.trim() -ne ""})
if ($datalines.length -lt 25)
{
  # Log message is empty. Show the error.
  [Console]::Error.WriteLine("Empty 'svn:log' properties are not allowed.")
  exit 3
}

exit 0

Este script por lotes permite que solo el usuario "svnmgr" cambie las propiedades de revisión:

IF "%3" == "svnmgr" (goto :label1) else (echo "Only the svnmgr user may change revision properties" >&2 )

exit 1
goto :eof

:label1
exit 0

Para usuarios de PC: la extensión .bat no funcionó para mí cuando se usaba en el mecanizado de Windows Server. Usé VisualSvn como Django Reinhardt sugirió, y creó un gancho con una extensión .cmd.

1. Vaya al directorio de repositorio SVN en la subcarpeta "ganchos", por ejemplo, "D: \ SVN \ hooks \"
2. cree el archivo vacío "pre-revprop-change.bat" allí
3. en el archivo escriba "exit 0" (sin "") y guárdelo
4. disfruta :)

(Esta solución seguramente tiene inconvenientes, ya que nada está marcado / prohibido. Pero para mi caso, un repositorio local que solo estoy usando, parece funcionar).