Cómo verificar si un proceso se ejecuta a través de un script por lotes

¿Cómo puedo verificar si una aplicación se ejecuta desde un archivo por lotes (cmd)?

No necesito iniciar otra instancia si ya se está ejecutando un programa. (No puedo cambiar la aplicación para que sea solo una instancia).

Además, la aplicación podría estar ejecutándose como cualquier usuario.

Otra posibilidad que se me ocurrió, inspirada en el uso de grep , es:

tasklist /FI "IMAGENAME eq myapp.exe" 2>NUL | find /I /N "myapp.exe">NUL
if "%ERRORLEVEL%"=="0" echo Program is running

No necesita guardar un archivo adicional, así que prefiero este método.

Así es como lo resolví:

tasklist /FI "IMAGENAME eq notepad.exe" /FO CSV > search.log

FOR /F %%A IN (search.log) DO IF %%~zA EQU 0 GOTO end

start notepad.exe

:end

del search.log

Lo anterior abrirá el Bloc de notas si aún no se está ejecutando.

Editar: tenga en cuenta que esto no encontrará aplicaciones ocultas de la lista de tareas. Esto incluirá cualquier tarea programada que se ejecute como un usuario diferente, ya que se oculta automáticamente.

¡Me gusta la solución de Chaosmaster! Pero busqué una solución que no inicie otro programa externo (como find.exe o findtr.exe ). Así que agregué la idea de la solución de Matt Lacey, que crea un archivo temporal también evitable. Al final pude encontrar una solución bastante simple, así que la comparto ...

SETLOCAL EnableExtensions
set EXE=myprog.exe
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% goto FOUND
echo Not running
goto FIN
:FOUND
echo Running
:FIN

Esto me está funcionando muy bien ...

La sugerencia de npocmaka de usar QPROCESS en lugar de TASKLIST es genial, pero su respuesta es tan grande y compleja que me siento obligado a publicar una versión bastante simplificada que, supongo, resolverá el problema de la mayoría de los usuarios no avanzados:

QPROCESS "myprocess.exe">NUL
IF %ERRORLEVEL% EQU 0 ECHO "Process running"

El código anterior se probó en Windows 7, con un usuario con derechos de administrador.

En Windows, puede usar el Instrumental de administración de Windows (WMI) para asegurarse de que no se inicien aplicaciones con la línea de comando especificada, por ejemplo:

wmic process where (name="nmake.exe") get commandline | findstr /i /c:"/f load.mak" /c:"/f build.mak" > NUL && (echo THE BUILD HAS BEEN STARTED ALREADY! > %ALREADY_STARTED% & exit /b 1)

TASKLIST | FINDSTR ProgramName || START "" "Path\ProgramName.exe"

Uso PV.exe de http://www.teamcti.com/pview/prcview.htm instalado en Program Files \ PV con un archivo por lotes como este:

@echo off
PATH=%PATH%;%PROGRAMFILES%\PV;%PROGRAMFILES%\YourProgram
PV.EXE YourProgram.exe >nul
if ERRORLEVEL 1 goto Process_NotFound
:Process_Found
echo YourProgram is running
goto END
:Process_NotFound
echo YourProgram is not running
YourProgram.exe
goto END
:END

La respuesta de TrueY parecía la solución más elegante, sin embargo, tuve que hacer algunos cambios porque no entendía exactamente qué estaba pasando. Permítanme aclarar las cosas para, con suerte, ahorrar algo de tiempo para la próxima persona.

Respuesta modificada de TrueY:

::Change the name of notepad.exe to the process .exe that you're trying to track
::Process names are CASE SENSITIVE, so notepad.exe works but Notepad.exe does NOT
::Do not change IMAGENAME
::You can Copy and Paste this into an empty batch file and change the name of
::notepad.exe to the process you'd like to track
::Also, some large programs take a while to no longer show as not running, so
::give this batch a few seconds timer to avoid a false result!!

@echo off
SETLOCAL EnableExtensions

set EXE=notepad.exe

FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% goto ProcessFound

goto ProcessNotFound

:ProcessFound

echo %EXE% is running
goto END
:ProcessNotFound
echo %EXE% is not running
goto END
:END
echo Finished!

De todos modos, espero que ayude. Sé que a veces leer la línea de comandos / lote puede ser un poco confuso a veces si eres un novato, como yo.

La respuesta proporcionada por Matt Lacey funciona para Windows XP. Sin embargo, en Windows Server 2003 la línea

 tasklist /FI "IMAGENAME eq notepad.exe" /FO CSV > search.log

devoluciones

INFORMACIÓN: no se están ejecutando tareas que coincidan con los criterios especificados.

que luego se lee mientras se ejecuta el proceso.

No tengo un montón de experiencia en secuencias de comandos por lotes, por lo que mi intención es buscar el nombre del proceso en el search.logarchivo y bombear los resultados a otro archivo y buscar cualquier salida.

tasklist /FI "IMAGENAME eq notepad.exe" /FO CSV > search.log

FINDSTR notepad.exe search.log > found.log

FOR /F %%A IN (found.log) DO IF %%~zA EQU 0 GOTO end

start notepad.exe

:end

del search.log
del found.log

Espero que esto ayude a alguien más.

Me gustan las herramientas WMICy TASKLIST, pero no están disponibles en las ediciones domésticas / básicas de QPROCESSWindows. Otra forma es usar el comando disponible en casi todas las máquinas Windows (para las que tienen servicios de terminal, creo que solo ganan XP sin SP2, así que prácticamente todos máquina de ventanas):

@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1
:: QPROCESS can display only the first 12 symbols of the running process
:: If other tool is used the line bellow could be deleted
set process_to_check=%process_to_check:~0,12%

QPROCESS * | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal

QPROCESSEl comando no es tan poderoso TASKLISTy está limitado en mostrar solo 12 símbolos del nombre del proceso, pero debe tenerse en cuenta si TASKLISTno está disponible.

Uso más simple donde usa el nombre si el proceso es un argumento (el .exesufijo es obligatorio en este caso cuando pasa el nombre ejecutable):

@echo off
:check_process
setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
:: .exe suffix is mandatory
set "process_to_check=%~1"


QPROCESS "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal

La diferencia entre dos formas de QPROCESSuso es que QPROCESS *enumerará todos los procesos y QPROCESS some.exefiltrará solo los procesos para el usuario actual.

El uso de WMIobjetos a través de Windows Script Host Exe en lugar de WMICtambién es una opción. Debería ejecutarse también en todas las máquinas Windows (excluyendo aquellas en las que WSH está apagado pero este es un caso raro). Aquí el archivo bat que enumera todos los procesos a través de WMI clases y se pueden usar en lugar de QPROCESSen el script anterior (es un híbrido jscript / bat y se debe guardar como .bat):

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **


@echo off
cscript //E:JScript //nologo "%~f0"
exit /b

************** end of JSCRIPT COMMENT **/


var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes =  new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    WScript.Echo( process.processID + "   " + process.Name );
}

Y una modificación que verificará si se está ejecutando un proceso:

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **


@echo off
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running
set process_to_check=%~1

cscript //E:JScript //nologo "%~f0" | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)

exit /b

************** end of JSCRIPT COMMENT **/


var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
var processes =  new Enumerator(colProcess);
for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    WScript.Echo( process.processID + "   " + process.Name );
}

Las dos opciones podrían usarse en máquinas que no tienen TASKLIST.

La última técnica es usar MSHTA. Esto se ejecutará en todas las máquinas con Windows desde XP y superiores y no depende de la configuración del host de script de Windows. Sin MSHTAembargo, la llamada de podría reducir un poco el rendimiento (nuevamente debe guardarse como bat):

@if (@X)==(@Y) @end /* JSCRIPT COMMENT **
@echo off

setlocal
if "%~1" equ "" echo pass the process name as forst argument && exit /b 1
:: first argument is the process you want to check if running

set process_to_check=%~1


mshta "about:<script language='javascript' src='file://%~dpnxf0'></script>" | find /i "%process_to_check%" >nul 2>&1 && (
    echo process %process_to_check%  is running
) || (
    echo process %process_to_check%  is not running
)
endlocal
exit /b
************** end of JSCRIPT COMMENT **/


   var fso= new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1);


   var winmgmts = GetObject("winmgmts:\\\\.\\root\\cimv2");
   var colProcess = winmgmts.ExecQuery("Select * from Win32_Process");
   var processes =  new Enumerator(colProcess);
   for (;!processes.atEnd();processes.moveNext()) {
    var process=processes.item();
    fso.Write( process.processID + "   " + process.Name + "\n");
   }
   close();

No sé cómo hacerlo con CMD incorporado, pero si tiene grep , puede intentar lo siguiente:

tasklist /FI "IMAGENAME eq myApp.exe" | grep myApp.exe
if ERRORLEVEL 1 echo "myApp is not running"

Solo menciono, si el nombre de su tarea es realmente largo, entonces no aparecerá en su totalidad en el tasklistresultado, por lo que podría ser más seguro (aparte de la localización) verificar lo contrario.

Variación de esta respuesta :

:: in case your task name is really long, check for the 'opposite' and find  the message when it's not there
tasklist /fi "imagename eq yourreallylongtasknamethatwontfitinthelist.exe" 2>NUL | find /I /N "no tasks are running">NUL
if "%errorlevel%"=="0" (
    echo Task Found
) else (
    echo Not Found Task
)

Estoy asumiendo ventanas aquí. Por lo tanto, deberá usar WMI para obtener esa información. Consulte los archivos de The Scripting Guy para obtener muchos ejemplos sobre cómo usar WMI desde un script.

Utilicé el guión proporcionado por Matt (2008-10-02). Lo único con lo que tuve problemas fue que no eliminaría el search.logarchivo. Espero porque tuve que ir cda otro lugar para comenzar mi programa. Volví cda donde está el archivo BAT y estoy search.log, pero aún así no se eliminaría. Así que resolví eso eliminando el search.logarchivo primero en lugar de último.

del search.log

tasklist /FI "IMAGENAME eq myprog.exe" /FO CSV > search.log

FOR /F %%A IN (search.log) DO IF %%-zA EQU 0 GOTO end

cd "C:\Program Files\MyLoc\bin"

myprog.exe myuser mypwd

:end

Usted debe verificar el nombre del proceso padre, véase El Proyecto Código artículo acerca de una solución basada en .NET ** .

Una forma no programática de verificar:

1. Inicie Cmd.exe
2. Inicie una aplicación (por ejemplo c:\windows\notepad.exe)
3. Verifique las propiedades del proceso Notepad.exe en Process Explorer
4. Verificar el proceso principal (Esto muestra cmd.exe)

Lo mismo se puede verificar obteniendo el nombre del proceso principal.

Sobre la base de la respuesta de vtrz y la respuesta de Samuel Renkert en otro tema , se me ocurrió la siguiente secuencia de comandos que sólo se ejecuta %EXEC_CMD%si no se está ejecutando:

@echo off
set EXEC_CMD="rsync.exe"
wmic process where (name=%EXEC_CMD%) get commandline | findstr /i %EXEC_CMD%> NUL
if errorlevel 1 (
    %EXEC_CMD% ...
) else (
    @echo not starting %EXEC_CMD%: already running.
)

Como se dijo antes, esto requiere privilegios administrativos.

Necesitaba una solución con un reintento. Este código se ejecutará hasta que se encuentre el proceso y luego lo matará. Puede establecer un tiempo de espera o cualquier cosa si lo desea.

Notas:

• El ".exe" es obligatorio
• Puede hacer que un archivo sea ejecutable con parámetros, versión a continuación

    :: Set programm you want to kill
    :: Fileextension is mandatory
    SET KillProg=explorer.exe

    :: Set waiting time between 2 requests in seconds
    SET /A "_wait=3"

    :ProcessNotFound
        tasklist /NH /FI "IMAGENAME eq %KillProg%" | FIND /I "%KillProg%"
        IF "%ERRORLEVEL%"=="0" (
            TASKKILL.EXE /F /T /IM %KillProg%
        ) ELSE (
            timeout /t %_wait%
            GOTO :ProcessNotFound
        )

taskkill.bat:

    :: Get program name from argumentlist
    IF NOT "%~1"=="" (
        SET "KillProg=%~1"
    ) ELSE (
        ECHO Usage: "%~nx0" ProgramToKill.exe & EXIT /B
    )

    :: Set waiting time between 2 requests in seconds
    SET /A "_wait=3"

    :ProcessNotFound
        tasklist /NH /FI "IMAGENAME eq %KillProg%" | FIND /I "%KillProg%"
        IF "%ERRORLEVEL%"=="0" (
            TASKKILL.EXE /F /T /IM %KillProg%
        ) ELSE (
            timeout /t %_wait%
            GOTO :ProcessNotFound
        )

Corre con .\taskkill.bat ProgramToKill.exe

Por lo general, ejecuto el siguiente comando en cmd prompt para verificar si mi program.exe se está ejecutando o no:

tasklist | grep program