¿Cómo puedo abrir shell en el búfer actual?

En la función "shell", esta línea muestra el buffer del shell y casi siempre su nuevo shell abierto en un marco aleatorio. Y tengo que cambiar los tampones, es molesto.

...
(pop-to-buffer buffer)
...

En documentos dice:

Si esa ventana está en un marco gráfico diferente, a ese marco se le dará foco de entrada si es posible.

No entiendo cómo puedo mostrar el búfer en el marco de destino, no soy lo suficientemente bueno en elisp. ¿Como puedo hacer eso? Gracias si alguien puede ayudar.

Supongo que el póster original significa apuntar a la ventana seleccionada actualmente en el mismo marco. En el caso de que el póster original desee apuntar a una ventana específica en un marco diferente, consulte este hilo relacionado para ver un ejemplo complejo: /programming/18346785/how-to-intercept-a-file- antes de que se abra y decida qué marco

Copié la función incorporada shelly creé una nueva llamada shell-get-buffer-create, que usa en with-current-buffer ...lugar de pop-to-buffer. Esta nueva función genera o localiza el *shell*búfer sin seleccionarlo en ninguna ventana.

Para mostrar el *shell*búfer en la ventana seleccionada actualmente, use:

(switch-to-buffer (shell-get-buffer-create))

o

(pop-to-buffer-same-window (shell-get-buffer-create))

o

(set-window-buffer (selected-window) (shell-get-buffer-create))

Creé una función personalizada llamada my-display-bufferque se puede mostrar en cuatro direcciones: izquierda, derecha, arriba o abajo. Hay tres posibilidades: (1) Si una ventana en el marco ya muestra el búfer de destino, simplemente reutilice la misma ventana. (2) Si ya hay una ventana en la dirección especificada en relación con la ventana seleccionada, muestre el búfer de destino en dicha ventana. (3) Si no hay una ventana en la dirección especificada, cree una en esa dirección y muestre el búfer de destino en dicha ventana.

Uso de muestra :

(my-display-buffer (shell-get-buffer-create) nil 'left)

o

(my-display-buffer (shell-get-buffer-create) nil 'right)

o

(my-display-buffer (shell-get-buffer-create) nil 'above)

o

(my-display-buffer (shell-get-buffer-create) nil 'below)

El código :

(require 'shell)

(defun shell-get-buffer-create (&optional buffer)
  "Run an inferior shell, with I/O through BUFFER (which defaults to `*shell*').
Interactively, a prefix arg means to prompt for BUFFER.
If `default-directory' is a remote file name, it is also prompted
to change if called with a prefix arg.

If BUFFER exists but shell process is not running, make new shell.
If BUFFER exists and shell process is running, just switch to BUFFER.
Program used comes from variable `explicit-shell-file-name',
 or (if that is nil) from the ESHELL environment variable,
 or (if that is nil) from `shell-file-name'.
If a file `~/.emacs_SHELLNAME' exists, or `~/.emacs.d/init_SHELLNAME.sh',
it is given as initial input (but this may be lost, due to a timing
error, if the shell discards input when it starts up).
The buffer is put in Shell mode, giving commands for sending input
and controlling the subjobs of the shell.  See `shell-mode'.
See also the variable `shell-prompt-pattern'.

To specify a coding system for converting non-ASCII characters
in the input and output to the shell, use \\[universal-coding-system-argument]
before \\[shell].  You can also specify this with \\[set-buffer-process-coding-system]
in the shell buffer, after you start the shell.
The default comes from `process-coding-system-alist' and
`default-process-coding-system'.

The shell file name (sans directories) is used to make a symbol name
such as `explicit-csh-args'.  If that symbol is a variable,
its value is used as a list of arguments when invoking the shell.
Otherwise, one argument `-i' is passed to the shell.

\(Type \\[describe-mode] in the shell buffer for a list of commands.)"
  (interactive
   (list
    (and current-prefix-arg
   (prog1
       (read-buffer "Shell buffer: "
        ;; If the current buffer is an inactive
        ;; shell buffer, use it as the default.
        (if (and (eq major-mode 'shell-mode)
           (null (get-buffer-process (current-buffer))))
            (buffer-name)
          (generate-new-buffer-name "*shell*")))
     (if (file-remote-p default-directory)
         ;; It must be possible to declare a local default-directory.
               ;; FIXME: This can't be right: it changes the default-directory
               ;; of the current-buffer rather than of the *shell* buffer.
         (setq default-directory
         (expand-file-name
          (read-directory-name
           "Default directory: " default-directory default-directory
           t nil))))))))
  (setq buffer (if (or buffer (not (derived-mode-p 'shell-mode))
                       (comint-check-proc (current-buffer)))
                   (get-buffer-create (or buffer "*shell*"))
                 ;; If the current buffer is a dead shell buffer, use it.
                 (current-buffer)))

  ;; On remote hosts, the local `shell-file-name' might be useless.
  (if (and (called-interactively-p 'any)
     (file-remote-p default-directory)
     (null explicit-shell-file-name)
     (null (getenv "ESHELL")))
      (with-current-buffer buffer
  (set (make-local-variable 'explicit-shell-file-name)
       (file-remote-p
        (expand-file-name
         (read-file-name
    "Remote shell path: " default-directory shell-file-name
    t shell-file-name))
        'localname))))

  ;; The buffer's window must be correctly set when we call comint (so
  ;; that comint sets the COLUMNS env var properly).
  (with-current-buffer buffer
    (unless (comint-check-proc buffer)
      (let* ((prog (or explicit-shell-file-name
           (getenv "ESHELL") shell-file-name))
       (name (file-name-nondirectory prog))
       (startfile (concat "~/.emacs_" name))
       (xargs-name (intern-soft (concat "explicit-" name "-args"))))
        (unless (file-exists-p startfile)
    (setq startfile (concat user-emacs-directory "init_" name ".sh")))
        (apply 'make-comint-in-buffer "shell" buffer prog
         (if (file-exists-p startfile) startfile)
         (if (and xargs-name (boundp xargs-name))
       (symbol-value xargs-name)
           '("-i")))
        (shell-mode))))
  buffer)

(defun my-display-buffer (buffer alist direction &optional size pixelwise)
"BUFFER:  The buffer that will be displayed.
ALIST:  See the doc-string of `display-buffer' for more information.
DIRECTION:  Must use one of these symbols:  'left 'right 'below 'above
SIZE:  See the doc-string for `split-window'.
PIXELWISE:  See the doc-string for `split-window'.
There are three possibilities:
-  (1) If a window on the frame already displays the target buffer,
then just reuse the same window.
-  (2) If there is already a window in the specified direction in relation
to the selected window, then display the target buffer in said window.
-  (3) If there is no window in the specified direction, then create one
in that direction and display the target buffer in said window."
  (let ((window
          (cond
            ((get-buffer-window buffer (selected-frame)))
            ((window-in-direction direction))
            (t
              (split-window (selected-window) size direction pixelwise)))))
    (window--display-buffer buffer window 'window alist display-buffer-mark-dedicated)
    window))

Y, aquí hay un eshell-get-buffer-createque funciona igual que el anterior ...

(require 'cl)
(require 'eshell)

(defun eshell-get-buffer-create (&optional arg)
"Create an interactive Eshell buffer.  Return the Eshell buffer,
creating it if needed.  The buffer used for Eshell sessions is
determined by the value of `eshell-buffer-name'.  A numeric prefix
arg (as in `C-u 42 M-x eshell RET') switches to the session with
that number, creating it if necessary.  A nonnumeric prefix arg
means to createa new session.  Returns the buffer selected (or created)."
  (interactive "P")
  (cl-assert eshell-buffer-name)
  (let ((buf (cond ((numberp arg)
        (get-buffer-create (format "%s<%d>"
                 eshell-buffer-name
                 arg)))
       (arg
        (generate-new-buffer eshell-buffer-name))
       (t
        (get-buffer-create eshell-buffer-name)))))
    (cl-assert (and buf (buffer-live-p buf)))
    (with-current-buffer buf
      (unless (derived-mode-p 'eshell-mode)
        (eshell-mode)))
    buf))

No es una respuesta directa a su pregunta, pero tal vez esta sea una solución para usted.

M-x install-package shell-pop

Para instalar el paquete shell-pop de melpa o melpa-stable. Luego evalúe (para probar en *scratch*via C-x C-e, más adelante en su .emacs)

(global-set-key (kbd "<C-M-return>") 'shell-pop)

Esto abre un shell en la parte inferior de su marco, en este caso al presionar ctrl-meta-ret. Repetir la secuencia del teclado vuelve a donde estabas.

Ver https://github.com/kyagi/shell-pop-el para más detalles.