¿Cómo puedo escapar del * en modo org para evitar la fuente en negrita?

Si escribo algo así como *shrug*en modo org, se fuente automáticamente como texto en negrita . ¿Cómo puedo evitar eso, es decir, haber *shrug*aparecido literalmente al exportar?

Editar:

Todavía quiero poder usar la fuente en negrita (sin tener que cambiar la sintaxis de estrella predeterminada para el texto en negrita), y no debería importar a qué formato de archivo se exporta mi archivo de organización, por ejemplo, debería funcionar para Markdown y HTML exportar.

Esto es algo importante , por eso está escrito en negrita. Pero para otra cosa, no tengo idea * encogerse de hombros *.

Esta respuesta está inspirada después de sugerencias colectivas en la lista GNU de emacs-org-mode para usar los caracteres org-entity( C-h i g (org) Special symbols) en \ast{}lugar de espacios de ancho cero (que sugerí en mi otra respuesta aquí ).

A continuación se muestra una solución genérica en la que el usuario no necesita recordar las entidades orgánicas para varios símbolos. Inserta la entidad de organización (si está disponible) cuando el usuario lo hace C-u SYMBOL; que funciona para C-u *, C-u /, C-u =, etc.

(defun modi/org-entity-get-name (char)
  "Return the entity name for CHAR. For example, return \"ast\" for *."
  (let ((ll (append org-entities-user
                    org-entities))
        e name utf8)
    (catch 'break
      (while ll
        (setq e (pop ll))
        (when (not (stringp e))
          (setq utf8 (nth 6 e))
          (when (string= char utf8)
            (setq name (car e))
            (throw 'break name)))))))

(defun modi/org-insert-org-entity-maybe (&rest args)
  "When the universal prefix C-u is used before entering any character,
    insert the character's `org-entity' name if available.

    If C-u prefix is not used and if `org-entity' name is not available, the
    returned value `entity-name' will be nil."
  ;; It would be fine to use just (this-command-keys) instead of
  ;; (substring (this-command-keys) -1) below in emacs 25+.
  ;; But if the user pressed "C-u *", then
  ;;  - in emacs 24.5, (this-command-keys) would return "^U*", and
  ;;  - in emacs 25.x, (this-command-keys) would return "*".
  ;; But in both versions, (substring (this-command-keys) -1) will return
  ;; "*", which is what we want.
  ;; http://thread.gmane.org/gmane.emacs.orgmode/106974/focus=106996
  (let ((pressed-key (substring (this-command-keys) -1))
        entity-name)
    (when (and (listp args) (eq 4 (car args)))
      (setq entity-name (modi/org-entity-get-name pressed-key))
      (when entity-name
        (setq entity-name (concat "\\" entity-name "{}"))
        (insert entity-name)
        (message (concat "Inserted `org-entity' "
                         (propertize entity-name
                                     'face 'font-lock-function-name-face)
                         " for the symbol "
                         (propertize pressed-key
                                     'face 'font-lock-function-name-face)
                         "."))))
    entity-name))

;; Run `org-self-insert-command' only if `modi/org-insert-org-entity-maybe'
;; returns nil.
(advice-add 'org-self-insert-command :before-until #'modi/org-insert-org-entity-maybe)

Entonces, cuando el usuario escribe C-u *, \ast{}se inserta y se muestra el siguiente mensaje en el área de eco,

Se insertó 'org-entity' \ ast {} para el símbolo *.

Si org-pretty-entitiesse establece en tarriba, el insertado \ast{}se mostrará como *.

Si org-entityno existe un para un carácter X y si el usuario hace C-u X , X simplemente se inserta 4 veces (como C-usuele ocurrir).

Uso del espacio unicode de espacio de ancho cero

Puede fallar el análisis de énfasis en negrita agregando un carácter de espacio de ancho cero (indicado por [ZWS] en los fragmentos a continuación) antes del primer asterisco o después del segundo asterisco.

Los dos fragmentos a continuación se exportaron bien a HTML en mis pruebas:

• [ZWS] antes del primer asterisco

  This is some *bold* test and this is ​[ZWS]*not bold*.
  

• [ZWS] después del segundo asterisco

  This is some *bold* test and this is *not bold*​[ZWS].
  

Puede ingresar el ESPACIO DE ANCHO CERO (nombre unicode) haciendo C-x 8 RET 200b RET.
Lo uso muy a menudo, así queC-x 8 0 lo he vinculado .

Actualizar

Según la discusión en la lista de correo emacs-org-mode , no se recomienda el uso de caracteres no ASCII para escapar; en su lugar org-entitiesdebe usarse si corresponde. También estuve de acuerdo con eso y se me ocurrió esta otra solución que hace que la inserción sea org-entitiesrealmente fácil ( C-u *en este caso).

Al pie de la letra, si realmente quiere decir usar algún marcado en el LaTeX exportado, entonces puede usarlo =*shrug*=. Sin embargo, si solo desea que se exporte como *shrug*y desea hacerlo todo el tiempo, le recomendaría filtros . Sin embargo, si solo necesita esto para algunos casos *shrug*, debe usar la alternativa sugerida por @wvxvw. Podrías hacer esto limpiamente usando macros . Algunos ejemplos siguen.

Filtros

(defun my-bold (contents backend info)
  (when (org-export-derived-backend-p backend 'latex)
    (replace-regexp-in-string "\\`\\\\textbf{\\(.+\\)}"
                              "\\\\ast{}\\1\\\\ast{}" contents)))

(add-to-list 'org-export-filter-bold-functions 'my-bold)

Esencialmente, el filtro anterior busca el \textbf{..}marcado en la cadena transcodificada y lo reemplaza \ast{}..\ast{}sin cambiar lo que haya dentro {..}. No he probado la expresión regular y la cadena de reemplazo, por lo que podría haber errores, pero se entiende la idea. De manera similar para cubrir otros backends, uno puede incluir fragmentos adicionales como este:

(when (org-export-derived-backend-p backend 'html)
   (replace-regexp-in-string "<b>\\(.+\\)</b>" "\&#2a;\\1\&#2a;" contents))

La misma advertencia se cumple para la expresión regular anterior.

Macros

Fuente de la organización:

#+macro: nobold @@latex:\ast{}$1\ast{}@@ @@html:&#2a;$1&#2a;@@

This text is *bold* this is nobold{{{not}}}

exporta a LaTeX como:

This text is \textbf{bold} this is \ast{}not\ast{}

y a HTML como:

This text is <b>bold</b> this is  &#2a;not&#2a;

Por supuesto, puede agregar tantos backends como desee a la macro.

Editar: como Kaushal señala en los comentarios, el fragmento de exportación para látex es opcional en este caso. Sin embargo, prefiero usarlos cuando se trata de látex desnudo, ya que me resulta bastante difícil hacer un seguimiento de la lista org-entitiesy las reglas específicas detrás de la identificación de látex desnudo en la fuente Org.

Nota:

• los ejemplos de filtro no han sido probados,
• No sé ninguno HTML, por lo que puede haber algunos errores en los bits respectivos.

Esto está controlado por la variable org-énfasis-alista, y puede modificarse fácilmente.

• Coloque el punto sobre el texto en negrita, use el comando what-cursor-position C-u C-x =para encontrar la cara, tenga en cuenta que tiene propiedad org-emphasis.
• Llama customize-groupy busca org-énfasis
• org-énfasis-alista debería aparecer, con varias opciones para marcar texto.
• Eliminar la entrada correspondiente a *
• Aplicar cambios y reiniciar org-mode o emacs