Cómo configurar ⌘ + H para habilitar mostrar archivos ocultos

Quiero que mi Mac muestre archivos ocultos cuando presiono ⌘ + H (como ubuntu). Puedo ver archivos ocultos al poner este defaults write com.apple.finder AppleShowAllFiles YEScomando en la terminal, pero quiero obtener un atajo de teclado para ello. Además, si other + H ya está siendo utilizado por algún otro proceso, avíseme cuál podría ser el acceso directo más cercano y más relacionado para este nuevo proceso y cómo asignarlo al proceso respectivo de mostrar archivos ocultos.

Editar en noviembre de 2018
Esto es todo discutible desde High Sierra. En Finder, Cmd ⌘ Shift ⇧ . [punto, punto final] alternará archivos invisibles sobre la marcha, no se necesita nada más.

Cmd ⌘ H es el acceso directo de todo el sistema para "Ocultar aplicación de primer plano"

Para intentar vincular un nuevo acceso directo a eso, tal vez podría usar Automator para agregar un Servicio, pero aún no sé cómo lo convencería de anular el valor predeterminado del Sistema existente.

Esto funciona como un Servicio si usa una clave que no es del sistema, pero no con Cmd ⌘ H

on run {input, parameters}

    set newHiddenVisiblesState to "YES"
    try
        set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
        if oldHiddenVisiblesState is in {"1", "YES"} then
            set newHiddenVisiblesState to "NO"
        end if
    end try
    do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState


    tell application "Finder"
        set theWindows to every Finder window
        repeat with i from 1 to number of items in theWindows
            set this_item to item i of theWindows
            set theView to current view of this_item
            if theView is list view then
                set current view of this_item to icon view
            else
                set current view of this_item to list view

            end if
            set current view of this_item to theView
        end repeat
    end tell

    return input
end run

Editar para El Capitan ...
He notado que la actualización de la ventana del Finder ya no funciona en El Capitan, por lo que esta es una versión modificada, dejando el Finder en su lugar.

on run {input, parameters}      
    --Toggle Invisibles, El Capitan Version     
set newHiddenVisiblesState to "YES"
try
    set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
    if oldHiddenVisiblesState is in {"1", "YES"} then
        set newHiddenVisiblesState to "NO"
    end if
end try
do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState & "; killall Finder"
end run

Supongo que podría hacer que funcione solo para el Finder, si especificó algún otro comando de teclado para Hide Finder, ya que es visible como un elemento del menú, sería posible anular solo para esa aplicación [poniendo algo 'inútil' como alternativa], dejándolo libre para luego usarlo Cmd ⌘ H para alternar invisibles solo desde el Finder.

Probado: funciona de esta manera

Cmd ⌘ Shift ⇧ . alternará la visualización de archivos ocultos en el buscador (en Sierra o posterior (pero funciona en el diálogo de abrir archivos en versiones anteriores)).